000100 IDENTIFICATION DIVISION.
000200 PROGRAM-ID.           PPOPN202.
000300*AUTHOR.             DDS TEAM.
000400*                        CMS.
000500*REMARKS.
000600*    EFFECTIVE JAN 1,2006  CONVERTED SOFTWARE TO CICS FORMAT
000700*          - OPENS PROV,MSAX AND CBSA FILES
000800*          - FINDS PROV RECORD
000900*          - LOADS THE MSAX AND CBSA TABLES
001000*          - CALLS THE DRIVER MODULE
001100 DATE-COMPILED.
001200****************************************************************
001300* PPOPN202 VERSION FOR FY 2020 PRICER                        ***
001400****************************************************************
001500 ENVIRONMENT DIVISION.
001600 CONFIGURATION SECTION.
001700 SOURCE-COMPUTER.            IBM-370.
001800 OBJECT-COMPUTER.            IBM-370.
001900 INPUT-OUTPUT  SECTION.
002000 FILE-CONTROL.
002100
002200     SELECT PROV-FILE ASSIGN      TO  UT-S-PPSPROV
002300            FILE STATUS IS PROV-STAT.
002400     SELECT MSAX-FILE ASSIGN      TO  UT-S-PPSMSAX
002500            FILE STATUS IS MSAX-STAT.
002600     SELECT F-CBSA-FILE ASSIGN    TO  UT-S-PPSCBSA
002700            FILE STATUS IS CBSA-STAT.
002800 DATA DIVISION.
002900 FILE SECTION.
003000
003100 FD  PROV-FILE
003200     RECORDING MODE IS F
003300     LABEL RECORDS ARE STANDARD
003400     BLOCK CONTAINS 0 RECORDS.
003500 01  PROV-REC.
003600     05  PROV-PART1                 PIC X(80).
003700     05  PROV-PART2                 PIC X(80).
003800     05  PROV-PART3                 PIC X(150).
003900
004000 FD  MSAX-FILE
004100     RECORDING MODE IS F
004200     LABEL RECORDS ARE STANDARD
004300     BLOCK CONTAINS 0 RECORDS.
004400 01  MSAX-REC.
004500     05  X-MSA-X.
004600         10  M-BLANK                PIC X(02).
004700         10  M-STATE                PIC 9(02).
004800     05  X-MSA REDEFINES X-MSA-X    PIC 9(04).
004900     05  X-SIZE                     PIC X(01).
005000     05  XE-DATE.
005100         10  XE-CC                  PIC 9(02).
005200         10  XE-YY                  PIC 9(02).
005300         10  XE-MM                  PIC 9(02).
005400         10  XE-DD                  PIC 9(02).
005500     05  FILLER                     PIC X(01).
005600     05  X-WAGE-INDX1               PIC S9(02)V9(04).
005700     05  FILLER                     PIC X(01).
005800     05  X-WAGE-INDX2               PIC S9(02)V9(04).
005900     05  FILLER                     PIC X(01).
006000     05  X-STATE-MSA-NAME           PIC X(51).
006100     05  FILLER                     PIC X(01).
006200
006300 FD  F-CBSA-FILE
006400     RECORDING MODE IS F
006500     LABEL RECORDS ARE STANDARD
006600     BLOCK CONTAINS 0 RECORDS.
006700 01  F-CBSA-REC.
006800     05  F-CBSA.
006900         10  F-CBSA-BLANK                PIC X(03).
007000         10  F-CBSA-STATE                PIC 9(02).
007100     05  F-CBSA9  REDEFINES F-CBSA       PIC 9(05).
007200     05  F-CBSA-SIZE             PIC X(01).
007300     05  F-CBSA-EFF-DATE.
007400         10  F-CBSA-CC           PIC 9(02).
007500         10  F-CBSA-YY           PIC 9(02).
007600         10  F-CBSA-MM           PIC 9(02).
007700         10  F-CBSA-DD           PIC 9(02).
007800     05  FILLER                  PIC X(01).
007900     05  F-CBSA-WAGE-INDX1       PIC S9(02)V9(04).
008000     05  FILLER                  PIC X(01).
008100     05  F-CBSA-WAGE-INDX2       PIC S9(02)V9(04).
008200     05  FILLER                  PIC X(01).
008300     05  F-CBSA-STATE-NAME       PIC X(50).
008400     05  FILLER                  PIC X(01).
008500
008600 WORKING-STORAGE SECTION.
008700 77  W-STORAGE-REF                  PIC X(48)  VALUE
008800     'I/O PRICER FILES- W O R K I N G   S T O R A G E'.
008900
009000 01  PPDRV202                       PIC X(08) VALUE 'PPDRV202'.
009100 01  TABLES-LOADED-SW               PIC 9(01)  VALUE 0.
009200 01  EOF-SW                         PIC 9(01)  VALUE 0.
009300
009400 01  PROV-STAT.
009500     02  PROV-STAT1     PIC X.
009600     02  PROV-STAT2     PIC X.
009700
009800 01  MSAX-STAT.
009900     02  MSAX-STAT1     PIC X.
010000     02  MSAX-STAT2     PIC X.
010100
010200 01  CBSA-STAT.
010300     02  CBSA-STAT1     PIC X.
010400     02  CBSA-STAT2     PIC X.
010500
010600 01  MSAX-WI-TABLE.
010700     05  M-MSAX-DATA                OCCURS 9000
010800                                    INDEXED BY MU1 MU2 MU3.
010900         10  M-MSAX-MSA             PIC X(4).
011000         10  M-MSAX-SIZE            PIC X(01).
011100         10  M-MSAX-EFF-DATE        PIC X(08).
011200         10  M-MSAX-WAGE-INDX1      PIC S9(02)V9(04).
011300         10  M-MSAX-WAGE-INDX2      PIC S9(02)V9(04).
011400
011500 01  CBSA-WI-TABLE.
011600     05  T-CBSA-DATA                  OCCURS 8000
011700                                    INDEXED BY MA1 MA2 MA3.
011800         10  T-CBSA                   PIC X(5).
011900         10  T-CBSA-SIZE              PIC X(01).
012000         10  T-CBSA-EFF-DATE          PIC X(08).
012100         10  T-CBSA-WAGE-INDX1        PIC S9(02)V9(04).
012200         10  T-CBSA-WAGE-INDX2        PIC S9(02)V9(04).
012300
012400******************************************************************
012500* THE PROVIDER SPECIFIC INFORMATION TABLE IS INITIALLY SET TO    *
012600* OCCUR 4000 TIMES. THIS NUMBER SHOULD BY ADJUSTED BY THE USER   *
012700* TO REFLECT THE NUMBER OF PROVIDER RECORDS PLUS EXPANSION. EACH *
012800* ENTRY COSTS 240 BYTES OF MEMORY. THIS FILE MUST BE IN PROVIDER *
012900* NUMBER, EFFECTIVE-DATE SEQUENCE.                               *
013000******************************************************************
013100 01  PROV-TABLE.
013200     05  PROV-ENTRIES               OCCURS 4000
013300                                    ASCENDING KEY IS PROV-NO
013400                                    INDEXED BY PX1 PX2 PX3.
013500         10  PROV-DATA1.
013600             15  PROV-NPI10.
013700                 20  PROV-NPI8       PIC X(08).
013800                 20  PROV-NPI-FILLER PIC X(02).
013900             15  PROV-NO             PIC X(06).
014000             15  PROV-EFF-DATE       PIC X(08).
014100             15  FILLER              PIC X(56).
014200 01  PROV-DATA-2.
014300     05  PROV-ENTRIES2               OCCURS 4000
014400                                     INDEXED BY PD2.
014500         10  PROV-DATA2              PIC X(80).
014600 01  PROV-DATA-3.
014700     05  PROV-ENTRIES3               OCCURS 4000
014800                                     INDEXED BY PD3.
014900         10  PROV-DATA3              PIC X(150).
015000
015100***************************************************************
015200*      THIS IS THE WAGE-INDEX RECORD THAT WILL BE PASSED TO   *
015300*      THE PPCAL001 PROGRAM THRU PPCAL046 FOR PROCESSING
015400***************************************************************
015500 01  WAGE-NEW-INDEX-RECORD.
015600     05  W-NEW-MSA               PIC 9(4).
015700     05  W-NEW-SIZE              PIC X(01).
015800         88  NEW-LARGE-URBAN       VALUE 'L'.
015900         88  NEW-OTHER-URBAN       VALUE 'O'.
016000         88  NEW-ALL-RURAL         VALUE 'R'.
016100     05  W-NEW-EFF-DATE.
016200          10  W-NEW-EFF-DATE-CC   PIC 9(2).
016300          10  W-NEW-EFF-DATE-YMD.
016400              15  W-NEW-EFF-DATE-YY   PIC 9(2).
016500              15  W-NEW-EFF-DATE-MM   PIC 9(2).
016600              15  W-NEW-EFF-DATE-DD   PIC 9(2).
016700     05  FILLER              PIC X.
016800     05  W-NEW-INDEX-RECORD      PIC S9(02)V9(04).
016900     05  W-NEW-PR-INDEX-RECORD   PIC S9(02)V9(04).
017000
017100***************************************************************
017200*      THIS IS THE WAGE-INDEX RECORD THAT WILL BE PASSED TO   *
017300*      THE PPCAL051 PROGRAM AND AFTER FOR PROCESSING
017400***************************************************************
017500 01  WAGE-NEW-CBSA-INDEX-RECORD.
017600     05  W-NEW-CBSA               PIC 9(5).
017700     05  W-NEW-CBSA-X  REDEFINES W-NEW-CBSA     PIC X(05).
017800     05  W-NEW-CBSA-SIZE              PIC X(01).
017900         88  NEW-CBSA-LARGE-URBAN       VALUE 'L'.
018000         88  NEW-CBSA-OTHER-URBAN       VALUE 'O'.
018100         88  NEW-CBSA-ALL-RURAL         VALUE 'R'.
018200     05  W-NEW-CBSA-EFF-DATE.
018300          10  W-NEW-CBSA-EFF-DATE-CC   PIC 9(2).
018400          10  W-NEW-CBSA-EFF-DATE-YMD.
018500              15  W-NEW-CBSA-EFF-DATE-YY   PIC 9(2).
018600              15  W-NEW-CBSA-EFF-DATE-MM   PIC 9(2).
018700              15  W-NEW-CBSA-EFF-DATE-DD   PIC 9(2).
018800     05  FILLER                      PIC X.
018900     05  W-NEW-CBSA-WI               PIC S9(02)V9(04).
019000     05  W-NEW-CBSA-PR-WI            PIC S9(02)V9(04).
019100
019200**************************************************************
019300*      THIS IS THE PROV-RECORD THAT WILL BE PASSED TO        *
019400*      THE PPDRV___ PROGRAM FOR PROCESSING                   *
019500**************************************************************
019600 01  PROV-NEW-HOLD.
019700     02  PROV-NEWREC-HOLD1.
019800         05  P-NEW-NPI10.
019900             10  P-NEW-NPI8             PIC X(08).
020000             10  P-NEW-NPI-FILLER       PIC X(02).
020100         05  P-NEW-PROVIDER-NO.
020200             10  P-NEW-STATE            PIC X(02).
020300             10  FILLER                 PIC X(04).
020400         05  P-NEW-DATE-DATA.
020500             10  P-NEW-EFF-DATE.
020600                 15  P-NEW-EFF-DT-CC    PIC 9(02).
020700                 15  P-NEW-EFF-DT-YY    PIC 9(02).
020800                 15  P-NEW-EFF-DT-MM    PIC 9(02).
020900                 15  P-NEW-EFF-DT-DD    PIC 9(02).
021000             10  P-NEW-FY-BEGIN-DATE.
021100                 15  P-NEW-FY-BEG-DT-CC PIC 9(02).
021200                 15  P-NEW-FY-BEG-DT-YY PIC 9(02).
021300                 15  P-NEW-FY-BEG-DT-MM PIC 9(02).
021400                 15  P-NEW-FY-BEG-DT-DD PIC 9(02).
021500             10  P-NEW-REPORT-DATE.
021600                 15  P-NEW-REPORT-DT-CC PIC 9(02).
021700                 15  P-NEW-REPORT-DT-YY PIC 9(02).
021800                 15  P-NEW-REPORT-DT-MM PIC 9(02).
021900                 15  P-NEW-REPORT-DT-DD PIC 9(02).
022000             10  P-NEW-TERMINATION-DATE.
022100                 15  P-NEW-TERM-DT-CC   PIC 9(02).
022200                 15  P-NEW-TERM-DT-YY   PIC 9(02).
022300                 15  P-NEW-TERM-DT-MM   PIC 9(02).
022400                 15  P-NEW-TERM-DT-DD   PIC 9(02).
022500         05  P-NEW-WAIVER-CODE          PIC X(01).
022600             88  P-NEW-WAIVER-STATE       VALUE 'Y'.
022700         05  P-NEW-INTER-NO             PIC 9(05).
022800         05  P-NEW-PROVIDER-TYPE        PIC X(02).
022900             88  P-N-SOLE-COMMUNITY-PROV    VALUE '01' '11'.
023000             88  P-N-REFERRAL-CENTER        VALUE '07' '11'
023100                                                  '15' '17'
023200                                                  '22'.
023300             88  P-N-INDIAN-HEALTH-SERVICE  VALUE '08'.
023400             88  P-N-REDESIGNATED-RURAL-YR1 VALUE '09'.
023500             88  P-N-REDESIGNATED-RURAL-YR2 VALUE '10'.
023600             88  P-N-SOLE-COM-REF-CENT      VALUE '11'.
023700             88  P-N-MDH-REBASED-FY90       VALUE '14' '15'.
023800             88  P-N-MDH-RRC-REBASED-FY90   VALUE '15'.
023900             88  P-N-SCH-REBASED-FY90       VALUE '16' '17'.
024000             88  P-N-SCH-RRC-REBASED-FY90   VALUE '17'.
024100             88  P-N-MEDICAL-ASSIST-FACIL   VALUE '18'.
024200             88  P-N-EACH                   VALUE '21' '22'.
024300             88  P-N-EACH-REFERRAL-CENTER   VALUE '22'.
024400             88  P-N-NHCMQ-II-SNF           VALUE '32'.
024500             88  P-N-NHCMQ-III-SNF          VALUE '33'.
024600         05  P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
024700             88  P-N-NEW-ENGLAND            VALUE  1.
024800             88  P-N-MIDDLE-ATLANTIC        VALUE  2.
024900             88  P-N-SOUTH-ATLANTIC         VALUE  3.
025000             88  P-N-EAST-NORTH-CENTRAL     VALUE  4.
025100             88  P-N-EAST-SOUTH-CENTRAL     VALUE  5.
025200             88  P-N-WEST-NORTH-CENTRAL     VALUE  6.
025300             88  P-N-WEST-SOUTH-CENTRAL     VALUE  7.
025400             88  P-N-MOUNTAIN               VALUE  8.
025500             88  P-N-PACIFIC                VALUE  9.
025600         05  P-NEW-CURRENT-DIV   REDEFINES
025700                    P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
025800             88  P-N-VALID-CENSUS-DIV    VALUE 1 THRU 9.
025900         05  P-NEW-MSA-DATA.
026000             10  P-NEW-CHG-CODE-INDEX       PIC X.
026100             10  P-NEW-GEO-LOC-MSAX         PIC X(04) JUST RIGHT.
026200             10  P-NEW-GEO-LOC-MSA9   REDEFINES
026300                             P-NEW-GEO-LOC-MSAX  PIC 9(04).
026400             10  P-NEW-GEO-LOC-MSA-AST REDEFINES
026500                             P-NEW-GEO-LOC-MSA9.
026600                 15  P-NEW-GEO-MSA-1ST    PIC X.
026700                 15  P-NEW-GEO-MSA-2ND    PIC X.
026800                 15  P-NEW-GEO-MSA-3RD    PIC X.
026900                 15  P-NEW-GEO-MSA-4TH    PIC X.
027000             10  P-NEW-WAGE-INDEX-LOC-MSA   PIC X(04) JUST RIGHT.
027100             10  P-NEW-STAND-AMT-LOC-MSA    PIC X(04) JUST RIGHT.
027200             10  P-NEW-STAND-AMT-LOC-MSA9
027300       REDEFINES P-NEW-STAND-AMT-LOC-MSA.
027400                 15  P-NEW-RURAL-1ST.
027500                     20  P-NEW-STAND-RURAL  PIC XX.
027600                         88  P-NEW-STD-RURAL-CHECK VALUE '  '.
027700                 15  P-NEW-RURAL-2ND        PIC XX.
027800         05  P-NEW-SOL-COM-DEP-HOSP-YR PIC XX.
027900                 88  P-NEW-SCH-YRBLANK    VALUE   '  '.
028000                 88  P-NEW-SCH-YR82       VALUE   '82'.
028100                 88  P-NEW-SCH-YR87       VALUE   '87'.
028200         05  P-NEW-LUGAR                    PIC X.
028300         05  P-NEW-TEMP-RELIEF-IND          PIC X.
028400             88  P-NEW-LOW-VOL25PCT     VALUE 'Y'.
028500***          Y = LOW VOLUME PERCENTAGE  25 % ADD ON
028600         05  P-NEW-FED-PPS-BLEND-IND        PIC X.
028700         05  P-NEW-STATE-CODE               PIC 9(02).
028800         05  P-NEW-STATE-CODE-X REDEFINES
028900             P-NEW-STATE-CODE               PIC X(02).
029000         05  FILLER                         PIC X(03).
029100     02  PROV-NEWREC-HOLD2.
029200         05  P-NEW-VARIABLES.
029300             10  P-NEW-CMI-ADJ-CPD       PIC  9(05)V9(02).
029400             10  P-NEW-COLA              PIC  9(01)V9(03).
029500             10  P-NEW-INTERN-RATIO      PIC  9(01)V9(04).
029600             10  P-NEW-BED-SIZE          PIC  9(05).
029700             10  P-NEW-CCR               PIC  9(01)V9(03).
029800             10  P-NEW-CMI               PIC  9(01)V9(04).
029900             10  P-NEW-SSI-RATIO         PIC  V9(04).
030000             10  P-NEW-MEDICAID-RATIO    PIC  V9(04).
030100             10  P-NEW-PPS-BLEND-YR-IND  PIC  X(01).
030200             10  P-NEW-PRUP-UPDTE-FACTOR PIC  9(01)V9(05).
030300             10  P-NEW-DSH-PERCENT       PIC  V9(04).
030400             10  P-NEW-FYE-DATE.
030500                 15  P-NEW-FYE-CC        PIC 99.
030600                 15  P-NEW-FYE-YY        PIC 99.
030700                 15  P-NEW-FYE-MM        PIC 99.
030800                 15  P-NEW-FYE-DD        PIC 99.
030900         05  P-NEW-CBSA-DATA.
031000             10  P-NEW-CBSA-SPEC-PAY-IND    PIC X.
031100                 88  P-NEW-CBSA-WI-GEO        VALUE 'N'.
031200                 88  P-NEW-CBSA-WI-RECLASS    VALUE 'Y'.
031300                 88  P-NEW-CBSA-WI-SPECIAL    VALUE '1' '2'.
031400***                  1 = ANYTHING OR HOLD HARMLESS WITH SPEC WI
031500***                  2 = RECLASS WITH SPEC WI
031600             10  P-NEW-CBSA-HOSP-QUAL-IND  PIC X.
031700                 88  P-NEW-CBSA-HOSP-QUAL-MET   VALUE '1'.
031800                 88  P-NEW-CBSA-HOSP-QUAL-25PER VALUE '2'.
031900                 88  P-NEW-CBSA-HOSP-QUAL-BOTH  VALUE '3'.
032000             10  P-NEW-CBSA-GEO-LOC        PIC X(05) JUST RIGHT.
032100             10  P-NEW-CBSA-GEO-LOC9  REDEFINES
032200                             P-NEW-CBSA-GEO-LOC  PIC 9(05).
032300             10  P-NEW-CBSA-GEO-LOC-AST REDEFINES
032400                             P-NEW-CBSA-GEO-LOC9.
032500                 15  P-NEW-CBSA-GEO-1ST    PIC X.
032600                 15  P-NEW-CBSA-GEO-2ND    PIC X.
032700                 15  P-NEW-CBSA-GEO-3RD    PIC X.
032800                 15  P-NEW-CBSA-GEO-4TH    PIC X.
032900                 15  P-NEW-CBSA-GEO-5TH    PIC X.
033000             10  P-NEW-CBSA-RECLASS-LOC    PIC X(05) JUST RIGHT.
033100             10  P-NEW-CBSA-STAND-AMT-LOC  PIC X(05) JUST RIGHT.
033200             10  P-NEW-CBSA-STAND-AMT-LOC-MSA9
033300       REDEFINES P-NEW-CBSA-STAND-AMT-LOC.
033400               15  P-NEW-CBSA-RURAL-1ST.
033500                   20  P-NEW-CBSA-STAND-RURAL  PIC XXX.
033600                      88  P-NEW-CBSA-STD-RURAL-CHECK VALUE '   '.
033700               15  P-NEW-CBSA-RURAL-2ND    PIC XX.
033800             10  P-NEW-CBSA-SPEC-WI          PIC 9(02)V9(04).
033900             10  P-NEW-CBSA-SPEC-WI-N  REDEFINES
034000                 P-NEW-CBSA-SPEC-WI          PIC 9(06).
034100     02  PROV-NEWREC-HOLD3.
034200         05  P-NEW-PASS-AMT-DATA.
034300             10  P-NEW-PASS-AMT-CAPITAL    PIC 9(04)V99.
034400             10  P-NEW-PASS-AMT-DIR-MED-ED PIC 9(04)V99.
034500             10  P-NEW-PASS-AMT-ORGAN-ACQ  PIC 9(04)V99.
034600             10  P-NEW-PASS-AMT-PLUS-MISC  PIC 9(04)V99.
034700         05  P-NEW-CAPI-DATA.
034800             15  P-NEW-CAPI-PPS-PAY-CODE   PIC X.
034900             15  P-NEW-CAPI-HOSP-SPEC-RATE PIC 9(04)V99.
035000             15  P-NEW-CAPI-OLD-HARM-RATE  PIC 9(04)V99.
035100             15  P-NEW-CAPI-NEW-HARM-RATIO PIC 9(01)V9999.
035200             15  P-NEW-CAPI-CSTCHG-RATIO   PIC 9V999.
035300             15  P-NEW-CAPI-NEW-HOSP       PIC X.
035400             15  P-NEW-CAPI-IME            PIC 9V9999.
035500             15  P-NEW-CAPI-EXCEPTIONS     PIC 9(04)V99.
035600         05  P-HVBP-HRR-DATA.
035700             15  P-NEW-VAL-BASED-PURCH-PARTIPNT PIC X.
035800             15  P-NEW-VAL-BASED-PURCH-ADJUST   PIC 9V9(11).
035900             15  P-NEW-HOSP-READMISSION-REDU    PIC X.
036000             15  P-NEW-HOSP-HRR-ADJUSTMT        PIC 9V9(4).
036100         05  P-MODEL1-BUNDLE-DATA.
036200             15  P-MODEL1-BUNDLE-DISPRCNT   PIC V999.
036300             15  P-HAC-REDUC-IND            PIC X.
036400             15  P-UNCOMP-CARE-AMOUNT       PIC 9(07)V99.
036500             15  P-EHR-REDUC-IND            PIC X.
036600             15  P-LV-ADJ-FACTOR            PIC 9V9(6).
036700         05  P-NEW-COUNTY-CODE              PIC 9(05).
036800         05  P-NEW-COUNTY-CODE-X REDEFINES
036900             P-NEW-COUNTY-CODE              PIC X(05).
037000         05  FILLER                         PIC X(47).
037100
037200***************************************************************
037300 LINKAGE SECTION.
037400
037500 01  BILL-NEW-DATA.
037600         10  B-N-NPI10.
037700            15  B-N-NPI8              PIC X(08).
037800            15  B-N-NPI-FILLER        PIC X(02).
037900         10  B-N-PROVIDER-NO          PIC X(06).
038000         10  B-N-REVIEW-CODE          PIC 9(02).
038100             88  N-VALID-REVIEW-CODE    VALUE 00 THRU 09 11.
038200             88  N-PAY-WITH-OUTLIER     VALUE 00 07.
038300             88  N-PAY-DAYS-OUTLIER     VALUE 01.
038400             88  N-PAY-COST-OUTLIER     VALUE 02.
038500             88  N-PAY-PERDIEM-DAYS     VALUE 03.
038600             88  N-PAY-AVG-STAY-ONLY    VALUE 04.
038700             88  N-PAY-XFER-WITH-COST   VALUE 05.
038800             88  N-PAY-XFER-NO-COST     VALUE 06.
038900             88  N-PAY-WITHOUT-COST     VALUE 07.
039000             88  N-PAY-DRG-480          VALUE 08.
039100             88  N-PAY-XFER-SPEC-DRG    VALUE 09 11.
039200             88  N-PAY-XFER-SPEC-DRG-NO-COST VALUE 11.
039300         10  B-N-DRG                  PIC 9(03).
039400         10  B-N-LOS                  PIC 9(03).
039500         10  B-N-COVERED-DAYS         PIC 9(03).
039600         10  B-N-LTR-DAYS             PIC 9(02).
039700         10  B-N-DISCHARGE-DATE.
039800             15  B-N-DISCHG-CC        PIC 9(02).
039900             15  B-N-DISCHG-YY        PIC 9(02).
040000             15  B-N-DISCHG-MM        PIC 9(02).
040100             15  B-N-DISCHG-DD        PIC 9(02).
040200         10  B-N-CHARGES-CLAIMED      PIC 9(07)V9(02).
040300         10  B-N-PRIN-PROC-CODE       PIC X(07).
040400         10  B-N-OTHER-PROC-CODE1     PIC X(07).
040500         10  B-N-OTHER-PROC-CODE2     PIC X(07).
040600         10  B-N-OTHER-PROC-CODE3     PIC X(07).
040700         10  B-N-OTHER-PROC-CODE4     PIC X(07).
040800         10  B-N-OTHER-PROC-CODE5     PIC X(07).
040900         10  B-N-OTHER-PROC-CODE6     PIC X(07).
041000         10  B-N-OTHER-PROC-CODE7     PIC X(07).
041100         10  B-N-OTHER-PROC-CODE8     PIC X(07).
041200         10  B-N-OTHER-PROC-CODE9     PIC X(07).
041300         10  B-N-OTHER-PROC-CODE10    PIC X(07).
041400         10  B-N-OTHER-PROC-CODE11    PIC X(07).
041500         10  B-N-OTHER-PROC-CODE12    PIC X(07).
041600         10  B-N-OTHER-PROC-CODE13    PIC X(07).
041700         10  B-N-OTHER-PROC-CODE14    PIC X(07).
041800         10  B-N-OTHER-PROC-CODE15    PIC X(07).
041900         10  B-N-OTHER-PROC-CODE16    PIC X(07).
042000         10  B-N-OTHER-PROC-CODE17    PIC X(07).
042100         10  B-N-OTHER-PROC-CODE18    PIC X(07).
042200         10  B-N-OTHER-PROC-CODE19    PIC X(07).
042300         10  B-N-OTHER-PROC-CODE20    PIC X(07).
042400         10  B-N-OTHER-PROC-CODE21    PIC X(07).
042500         10  B-N-OTHER-PROC-CODE22    PIC X(07).
042600         10  B-N-OTHER-PROC-CODE23    PIC X(07).
042700         10  B-N-OTHER-PROC-CODE24    PIC X(07).
042800         10  B-N-OTHER-DIAG-CODE1   PIC X(07).
042900         10  B-N-OTHER-DIAG-CODE2   PIC X(07).
043000         10  B-N-OTHER-DIAG-CODE3   PIC X(07).
043100         10  B-N-OTHER-DIAG-CODE4   PIC X(07).
043200         10  B-N-OTHER-DIAG-CODE5   PIC X(07).
043300         10  B-N-OTHER-DIAG-CODE6   PIC X(07).
043400         10  B-N-OTHER-DIAG-CODE7   PIC X(07).
043500         10  B-N-OTHER-DIAG-CODE8   PIC X(07).
043600         10  B-N-OTHER-DIAG-CODE9   PIC X(07).
043700         10  B-N-OTHER-DIAG-CODE10  PIC X(07).
043800         10  B-N-OTHER-DIAG-CODE11  PIC X(07).
043900         10  B-N-OTHER-DIAG-CODE12  PIC X(07).
044000         10  B-N-OTHER-DIAG-CODE13  PIC X(07).
044100         10  B-N-OTHER-DIAG-CODE14  PIC X(07).
044200         10  B-N-OTHER-DIAG-CODE15  PIC X(07).
044300         10  B-N-OTHER-DIAG-CODE16  PIC X(07).
044400         10  B-N-OTHER-DIAG-CODE17  PIC X(07).
044500         10  B-N-OTHER-DIAG-CODE18  PIC X(07).
044600         10  B-N-OTHER-DIAG-CODE19  PIC X(07).
044700         10  B-N-OTHER-DIAG-CODE20  PIC X(07).
044800         10  B-N-OTHER-DIAG-CODE21  PIC X(07).
044900         10  B-N-OTHER-DIAG-CODE22  PIC X(07).
045000         10  B-N-OTHER-DIAG-CODE23  PIC X(07).
045100         10  B-N-OTHER-DIAG-CODE24  PIC X(07).
045200         10  B-N-OTHER-DIAG-CODE25  PIC X(07).
045300         10  B-N-DEMO-DATA.
045400             15  B-N-DEMO-CODE1        PIC X(02).
045500             15  B-N-DEMO-CODE2        PIC X(02).
045600             15  B-N-DEMO-CODE3        PIC X(02).
045700             15  B-N-DEMO-CODE4        PIC X(02).
045800         10  B-N-NDC-DATA.
045900             15  B-N-NDC-NUMBER        PIC X(11).
046000         10  FILLER                     PIC X(73).
046100
046200 01  PPS-DATA.
046300         10  PPS-RTC                PIC 9(02).
046400         10  PPS-WAGE-INDX          PIC 9(02)V9(04).
046500         10  PPS-OUTLIER-DAYS       PIC 9(03).
046600         10  PPS-AVG-LOS            PIC 9(02)V9(01).
046700         10  PPS-DAYS-CUTOFF        PIC 9(02)V9(01).
046800         10  PPS-OPER-IME-ADJ       PIC 9(06)V9(02).
046900         10  PPS-TOTAL-PAYMENT      PIC 9(07)V9(02).
047000         10  PPS-OPER-HSP-PART      PIC 9(06)V9(02).
047100         10  PPS-OPER-FSP-PART      PIC 9(06)V9(02).
047200         10  PPS-OPER-OUTLIER-PART  PIC 9(07)V9(02).
047300         10  PPS-REG-DAYS-USED      PIC 9(03).
047400         10  PPS-LTR-DAYS-USED      PIC 9(02).
047500         10  PPS-OPER-DSH-ADJ       PIC 9(06)V9(02).
047600         10  PPS-CALC-VERS          PIC 9(05).
047700
047800 01  PRICER-OPT-VERS-SW.
047900     02  PRICER-OPTION-SW               PIC X(01).
048000         88  ALL-TABLES-PASSED          VALUE 'A'.
048100         88  PROV-RECORD-PASSED         VALUE 'P'.
048200         88  ADDITIONAL-VARIABLES       VALUE 'M'.
048300     02  PPS-VERSIONS.
048400         10  PPDRV-VERSION              PIC X(05).
048500
048600 01  PPS-ADDITIONAL-VARIABLES.
048700     02  PPS-OPERATION-VARIABLES.
048800         05  PPS-HSP-PCT                PIC 9(01)V9(02).
048900         05  PPS-FSP-PCT                PIC 9(01)V9(02).
049000         05  PPS-NAT-PCT                PIC 9(01)V9(02).
049100         05  PPS-REG-PCT                PIC 9(01)V9(02).
049200         05  PPS-CMI-ADJ-CPD            PIC 9(05)V9(02).
049300         05  PPS-UPDATE-FACTOR          PIC 9(01)V9(05).
049400         05  PPS-DRG-WT                 PIC 9(02)V9(04).
049500         05  PPS-NAT-LABOR              PIC 9(05)V9(02).
049600         05  PPS-NAT-NLABOR             PIC 9(05)V9(02).
049700         05  PPS-REG-LABOR              PIC 9(05)V9(02).
049800         05  PPS-REG-NLABOR             PIC 9(05)V9(02).
049900         05  PPS-OPER-COLA              PIC 9(01)V9(03).
050000         05  PPS-INTERN-RATIO           PIC 9(01)V9(04).
050100         05  PPS-OPER-OUTLIER           PIC 9(07)V9(09).
050200         05  PPS-OPER-BILL-COSTS        PIC 9(07)V9(09).
050300         05  PPS-OPER-DOLLAR-THRESHOLD  PIC 9(07)V9(09).
050400         05  PPS-DSCHG-FRCTN            PIC 9(1)V9999.
050500         05  PPS-DRG-WT-FRCTN           PIC 9(2)V9999.
050600         05  PPS-CAPITAL-VARIABLES.
050700             10  PPS-CAPI-TOTAL-PAY         PIC S9(07)V9(02).
050800             10  PPS-CAPI-HSP               PIC S9(07)V9(02).
050900             10  PPS-CAPI-FSP               PIC S9(07)V9(02).
051000             10  PPS-CAPI-OUTLIER           PIC S9(07)V9(02).
051100             10  PPS-CAPI-OLD-HARM          PIC S9(07)V9(02).
051200             10  PPS-CAPI-DSH-ADJ           PIC S9(07)V9(02).
051300             10  PPS-CAPI-IME-ADJ           PIC S9(07)V9(02).
051400             10  PPS-CAPI-EXCEPTIONS        PIC S9(07)V9(02).
051500         05  PPS-CAPITAL2-VARIABLES.
051600             10  PPS-CAPI2-PAY-CODE          PIC X(1).
051700             10  PPS-CAPI2-B-FSP             PIC S9(07)V9(02).
051800             10  PPS-CAPI2-B-OUTLIER         PIC S9(07)V9(02).
051900         05  PPS-OTHER-VARIABLES.
052000             10  PPS-NON-TEMP-RELIEF-PAYMENT PIC 9(07)V9(02).
052100             10  PPS-NEW-TECH-PAY-ADD-ON     PIC 9(07)V9(02).
052200             10  PPS-ISLET-ISOL-PAY-ADD-ON   PIC 9(07)V9(02).
052300             10  PPS-LOW-VOL-PAYMENT         PIC 9(07)V9(02).
052400         10  PPS-HVBP-HRR-DATA.
052500             15  PPS-VAL-BASED-PURCH-PARTIPNT PIC X.
052600             15  PPS-VAL-BASED-PURCH-ADJUST   PIC 9V9(11).
052700             15  PPS-HOSP-READMISS-REDUCTN    PIC X.
052800             15  PPS-HOSP-HRR-ADJUSTMT        PIC 9V9(4).
052900         10  PPS-OPERATNG-DATA.
053000             15  PPS-MODEL1-BUNDLE-DISPRCNT  PIC V999.
053100             15  PPS-OPER-BASE-DRG-PAY       PIC 9(08)V99.
053200             15  PPS-OPER-HSP-AMT            PIC 9(08)V99.
053300         10  PPS-PC-VARIABLES.
053400             15  PPS-OPER-DSH                PIC 9(01)V9(04).
053500             15  PPS-CAPI-DSH                PIC 9(01)V9(04).
053600             15  PPS-CAPI-HSP-PCT            PIC 9(01)V9(02).
053700             15  PPS-CAPI-FSP-PCT            PIC 9(01)V9(04).
053800             15  PPS-ARITH-ALOS              PIC 9(02)V9(01).
053900             15  PPS-PR-WAGE-INDEX           PIC 9(02)V9(04).
054000             15  PPS-TRANSFER-ADJ            PIC 9(01)V9(04).
054100             15  PPS-PC-HMO-FLAG             PIC X(01).
054200             15  PPS-PC-COT-FLAG             PIC X(01).
054300             15  PPS-OPER-HSP-PART2          PIC 9(07)V9(02).
054400             15  PPS-BUNDLE-ADJUST-AMT       PIC S9(07)V99.
054500         10  PPS-ADDITIONAL-PAY-INFO-DATA.
054600             15  PPS-UNCOMP-CARE-AMOUNT       PIC S9(07)V9(2).
054700             15  PPS-BUNDLE-ADJUST-AMT        PIC S9(07)V9(2).
054800             15  PPS-VAL-BASED-PURCH-ADJUST-AMT PIC S9(07)V9(2).
054900             15  PPS-READMIS-ADJUST-AMT       PIC S9(07)V9(2).
055000         10  PPS-ADDITIONAL-PAY-INFO-DATA2.
055100             15  PPS-HAC-PROG-REDUC-IND      PIC X.
055200             15  PPS-EHR-PROG-REDUC-IND      PIC X.
055300             15  PPS-EHR-ADJUST-AMT          PIC S9(07)V9(02).
055400             15  PPS-STNDRD-VALUE            PIC S9(07)V9(02).
055500             15  PPS-FLX6-PAYMENT            PIC S9(07)V9(02).
055600             15  PPS-FLX7-PAYMENT            PIC S9(07)V9(02).
055700         10  PPS-FILLER                      PIC X(0897).
055800*************************************************************
055900
056000 01  PROV-RECORD-FROM-USER.
056100     05  PROV-REC1                  PIC X(80).
056200     05  PROV-REC2                  PIC X(80).
056300     05  PROV-REC3                  PIC X(150).
056400
056500 01  MSAX-TABLE-FROM-USER.
056600     05  FILLER                     PIC X(32000).
056700     05  FILLER                     PIC X(30000).
056800     05  FILLER                     PIC X(30000).
056900
057000 01  CBSA-TABLE-FROM-USER.
057100     05  FILLER                     PIC X(32000).
057200     05  FILLER                     PIC X(30000).
057300     05  FILLER                     PIC X(30000).
057400
057500*******************************************************
057600*    HOLD VARIABLES POPULATED IN PPCAL___***          *
057700*******************************************************
057800 COPY PPHOLDAR.
057900
058000******************************************************************
058100 PROCEDURE DIVISION  USING BILL-NEW-DATA
058200                           PPS-DATA
058300                           PRICER-OPT-VERS-SW
058400                           PPS-ADDITIONAL-VARIABLES
058500                           PPHOLDAR-HOLD-AREA
058600                           PROV-RECORD-FROM-USER
058700                           MSAX-TABLE-FROM-USER
058800                           CBSA-TABLE-FROM-USER.
058900
059000******************************************************************
059100*    PROCESSING:
059200*        A. I/O THE PRICER FILES
059300*        B. THIS MODULE WILL LOAD ALL TABLES THE FIRST TIME THIS
059400*           SUBROUTINE IS CALLED.
059500*        C. ALL FILES WILL BE PASSED TO THE PPDRV___ PROGRAM.
059600******************************************************************
059700
059800     MOVE ALL '0' TO PPS-DATA.
059900
060000******************************************************************
060100
060200 0010-LOAD-TABLES.
060300     IF  PRICER-OPTION-SW  = 'A'
060400         PERFORM 1900-OPTION-SW-A THRU 1900-EXIT
060500     ELSE
060600     IF  PRICER-OPTION-SW  = 'P'
060700         PERFORM 2000-OPTION-SW-P THRU 2000-EXIT
060800     ELSE
060900         PERFORM 2100-OPTION-SW THRU 2100-EXIT.
061000
061100******************************************************************
061200***  GET THE PROVIDER RECORD TO BE PASSED TO PPDRV___
061300
061400 0020-GET-PROVIDER.
061500
061600     IF PROV-RECORD-PASSED OR ALL-TABLES-PASSED
061700*       PERFORM 1350-N-CHECK-MSA
061800        MOVE 00 TO PPS-RTC
061900     ELSE
062000        PERFORM 1200-GET-THIS-PROVIDER THRU 1200-EXIT.
062100
062200***     RTC = 51  --  PROVIDER NOT FOUND
062300     IF PPS-RTC = 51
062400          MOVE ALL '0' TO  PPS-ADDITIONAL-VARIABLES
062500          GOBACK.
062600
062700******************************************************************
062800
062900     CALL  PPDRV202 USING BILL-NEW-DATA
063000                          PPS-DATA
063100                          PRICER-OPT-VERS-SW
063200                          PPS-ADDITIONAL-VARIABLES
063300                          PROV-NEW-HOLD
063400                          MSAX-WI-TABLE
063500                          CBSA-WI-TABLE
063600                          PPHOLDAR-HOLD-AREA.
063700      GOBACK.
063800******************************************************************
063900
064000 1200-GET-THIS-PROVIDER.
064100***************************************************************
064200*    ON A PROVIDER BREAK:                                     *
064300*        FIND THE NEW PROVIDER SPECIFIC DATA ELEMENTS         *
064400*    NOTE: IF BILLS ARE BATCHED BY PROVIDER, FEWER TABLE      *
064500*             SEARCHES WILL BE NECESSARY.                     *
064600***************************************************************
064700     IF  B-N-PROVIDER-NO NOT = P-NEW-PROVIDER-NO
064800         SET PX2 TO 1
064900         SEARCH PROV-ENTRIES VARYING PX2
065000             AT END
065100                 MOVE 51 TO PPS-RTC
065200                 GO TO 1200-EXIT
065300             WHEN B-N-PROVIDER-NO = PROV-NO (PX2)
065400                 MOVE 00 TO PPS-RTC.
065500
065600     MOVE PROV-DATA1 (PX2) TO PROV-NEWREC-HOLD1.
065700     SET PD2 TO PX2.
065800     SET PD3 TO PX2.
065900     MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2.
066000     MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3.
066100
066200*    PERFORM 1350-N-CHECK-MSA.
066300
066400     PERFORM 1300-GET-CURR-PROV THRU 1300-EXIT VARYING PX3
066500         FROM PX2 BY 1 UNTIL PROV-NO (PX3) NOT =
066600         B-N-PROVIDER-NO OR PROV-NO (PX3) = '999999'.
066700
066800 1200-EXIT.  EXIT.
066900
067000 1300-GET-CURR-PROV.
067100     IF  B-N-DISCHARGE-DATE NOT < PROV-EFF-DATE (PX3)
067200         MOVE PROV-DATA1 (PX3) TO PROV-NEWREC-HOLD1
067300         SET PD2 TO PX3
067400         SET PD3 TO PX3
067500         MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2
067600         MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3.
067700*        PERFORM 1350-N-CHECK-MSA.
067800
067900 1300-EXIT.  EXIT.
068000
068100*1350-N-CHECK-MSA.
068200*
068300*    IF P-NEW-EFF-DATE < 20041001
068400*       IF (P-NEW-WAGE-INDEX-LOC-MSA = '    ' OR
068500*           P-NEW-WAGE-INDEX-LOC-MSA = '0000')
068600*           MOVE P-NEW-GEO-LOC-MSA9 TO P-NEW-WAGE-INDEX-LOC-MSA.
068700*    IF P-NEW-EFF-DATE < 20041001
068800*       IF (P-NEW-STAND-AMT-LOC-MSA = '    ' OR
068900*           P-NEW-STAND-AMT-LOC-MSA = '0000')
069000*           MOVE P-NEW-GEO-LOC-MSA9 TO P-NEW-STAND-AMT-LOC-MSA.
069100*
069200*    IF P-NEW-EFF-DATE > 20040930
069300*       IF (P-NEW-CBSA-RECLASS-LOC = '     ' OR
069400*           P-NEW-CBSA-RECLASS-LOC = '00000')
069500*           MOVE P-NEW-CBSA-GEO-LOC9 TO P-NEW-CBSA-RECLASS-LOC.
069600*    IF P-NEW-EFF-DATE > 20040930
069700*       IF (P-NEW-CBSA-STAND-AMT-LOC = '     ' OR
069800*           P-NEW-CBSA-STAND-AMT-LOC = '00000')
069900*           MOVE P-NEW-CBSA-GEO-LOC9 TO P-NEW-CBSA-STAND-AMT-LOC.
070000*
070100*1350-N-EXIT.  EXIT.
070200*
070300******************************************************************
070400 1500-LOAD-ALL-TABLES.
070500***************************************************************
070600*    THE FIRST TIME CALLED:                                   *
070700*        LOAD ALL TABLES SUPPLIED BY CMS                      *
070800*        LOAD THE PROVIDER SPECIFIC TABLE SUPPLIED BY         *
070900*             THE INTERMEDIARY.                               *
071000***************************************************************
071100     MOVE HIGH-VALUES TO MSAX-WI-TABLE.
071200     MOVE HIGH-VALUES TO CBSA-WI-TABLE.
071300     MOVE ALL '9' TO PROV-NEW-HOLD.
071400     MOVE ALL '9' TO PROV-TABLE.
071500     MOVE ALL '9' TO PROV-DATA-2.
071600     MOVE ALL '9' TO PROV-DATA-3.
071700     OPEN  INPUT  PROV-FILE.
071800     MOVE 0 TO EOF-SW.
071900     SET PX1 TO EOF-SW.
072000
072100     PERFORM 1600-READ-PROV-FILE THRU 1600-EXIT
072200                           UNTIL EOF-SW = 1.
072300
072400     CLOSE        PROV-FILE.
072500     PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT.
072600     PERFORM 1750-LOAD-CBSA-FILE THRU 1750-EXIT.
072700
072800 1500-EXIT.  EXIT.
072900
073000 1600-READ-PROV-FILE.
073100     READ PROV-FILE
073200         AT END
073300             SET PX1 UP BY 1
073400             MOVE ALL '9' TO PROV-DATA1 (PX1)
073500             SET PD2 TO PX1
073600             SET PD3 TO PX1
073700             MOVE ALL '9' TO PROV-DATA2 (PD2)
073800             MOVE ALL '9' TO PROV-DATA3 (PD3)
073900             MOVE '999999' TO P-NEW-PROVIDER-NO
074000             MOVE 1 TO EOF-SW.
074100
074200     IF  EOF-SW = 0
074300         SET PX1 UP BY 1
074400         MOVE PROV-PART1 TO PROV-DATA1 (PX1)
074500         SET PD2 TO PX1
074600         SET PD3 TO PX1
074700         MOVE PROV-PART2 TO PROV-DATA2 (PD2)
074800         MOVE PROV-PART3 TO PROV-DATA3 (PD3).
074900
075000 1600-EXIT.  EXIT.
075100
075200 1700-LOAD-MSAX-FILE.
075300     OPEN  INPUT  MSAX-FILE.
075400     MOVE 0 TO EOF-SW.
075500     SET MU3 TO EOF-SW.
075600
075700     PERFORM 1800-READ-MSAX-FILE THRU 1800-EXIT
075800                      UNTIL EOF-SW = 1.
075900     CLOSE        MSAX-FILE.
076000
076100 1700-EXIT.  EXIT.
076200
076300 1750-LOAD-CBSA-FILE.
076400     OPEN  INPUT  F-CBSA-FILE.
076500     MOVE 0 TO EOF-SW.
076600     SET MA3 TO EOF-SW.
076700
076800     PERFORM 1850-READ-CBSA-FILE THRU 1850-EXIT
076900                      UNTIL EOF-SW = 1.
077000     CLOSE  F-CBSA-FILE.
077100
077200 1750-EXIT.  EXIT.
077300
077400 1800-READ-MSAX-FILE.
077500     READ MSAX-FILE
077600         AT END
077700             MOVE 1 TO EOF-SW.
077800
077900     IF  EOF-SW = 0
078000             IF  XE-DATE > '19860930' OR
078100                (M-STATE = '98' OR '99')
078200                SET MU3 UP BY 1
078300                MOVE X-MSA-X      TO M-MSAX-MSA        (MU3)
078400                MOVE X-SIZE       TO M-MSAX-SIZE       (MU3)
078500                MOVE XE-DATE      TO M-MSAX-EFF-DATE   (MU3)
078600                MOVE X-WAGE-INDX1 TO M-MSAX-WAGE-INDX1 (MU3)
078700                MOVE X-WAGE-INDX2 TO M-MSAX-WAGE-INDX2 (MU3).
078800
078900 1800-EXIT.  EXIT.
079000
079100 1850-READ-CBSA-FILE.
079200     READ F-CBSA-FILE
079300         AT END
079400             MOVE 1 TO EOF-SW.
079500
079600     IF  EOF-SW = 0
079700             IF  F-CBSA-EFF-DATE > '20030930' OR
079800                (F-CBSA-STATE = '98' OR '99')
079900                SET MA3 UP BY 1
080000            MOVE F-CBSA            TO T-CBSA            (MA3)
080100            MOVE F-CBSA-SIZE       TO T-CBSA-SIZE       (MA3)
080200            MOVE F-CBSA-EFF-DATE   TO T-CBSA-EFF-DATE   (MA3)
080300            MOVE F-CBSA-WAGE-INDX1 TO T-CBSA-WAGE-INDX1 (MA3)
080400            MOVE F-CBSA-WAGE-INDX2 TO T-CBSA-WAGE-INDX2 (MA3).
080500
080600 1850-EXIT.  EXIT.
080700
080800 1900-OPTION-SW-A.
080900     MOVE ALL '9'               TO PROV-NEW-HOLD.
081000     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
081100     IF  TABLES-LOADED-SW = 0
081200         MOVE HIGH-VALUES           TO MSAX-WI-TABLE
081300         MOVE MSAX-TABLE-FROM-USER  TO MSAX-WI-TABLE
081400         MOVE HIGH-VALUES           TO CBSA-WI-TABLE
081500         MOVE CBSA-TABLE-FROM-USER  TO CBSA-WI-TABLE
081600         MOVE 1 TO TABLES-LOADED-SW.
081700
081800 1900-EXIT.  EXIT.
081900
082000 2000-OPTION-SW-P.
082100     MOVE ALL '9'               TO PROV-NEW-HOLD.
082200     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
082300     IF  TABLES-LOADED-SW = 0
082400         MOVE HIGH-VALUES       TO MSAX-WI-TABLE
082500         MOVE HIGH-VALUES       TO CBSA-WI-TABLE
082600         PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT
082700         PERFORM 1750-LOAD-CBSA-FILE THRU 1750-EXIT
082800         MOVE 1 TO TABLES-LOADED-SW.
082900
083000 2000-EXIT.  EXIT.
083100
083200 2100-OPTION-SW.
083300     IF  TABLES-LOADED-SW = 0
083400         PERFORM 1500-LOAD-ALL-TABLES THRU 1500-EXIT
083500         MOVE 1 TO TABLES-LOADED-SW.
083600
083700 2100-EXIT.  EXIT.
083800
083900***************************************************************
084000******       L A S T   S O U R C E   S T A T E M E N T    *****
