000100 IDENTIFICATION DIVISION.
000200 PROGRAM-ID. LTOPN182.
000300*AUTHOR.     CENTERS FOR MEDICARE AND MEDICAID SERVICES
000400*REMARKS.    - OPENS THE PROV FILE, MSAX FILE, CBSAX FILE, AND
000500*              IPPS CBSAX FILE
000600*            - FINDS PROV RECORD FOR THE GIVEN BILL TO BE
000700*              PASSED TO THE LTDRV___ MODULE
000800*            - LOADS THE MSAX, CBSAX, & IPPS CBSAX TABLES
000900*            - CALLS THE LTDRV___ MODULE
001000 DATE-COMPILED.
001100****************************************************************
001200*                                                              *
001300*   THIS SUBROUTINE IS FURNISHED BY THE CENTERS FOR MEDICARE   *
001400*   AND MEDICAID SERVICES.                                     *
001500*   IT IS TO BE USED AS AN AID IN IMPLEMENTING PROSPECTIVE     *
001600*   PAYMENT FOR LONG TERM CARE HOSPITALS.                      *
001700*   THE RESPONSIBILITY FOR INSTALLING, MODIFYING, TESTING,     *
001800*   MAINTAINING, AND VERIFYING THE ACCURACY OF THIS PROGRAM    *
001900*   IS THAT OF THE USER.                                       *
002000*                  *  *  *  *  *  *  *  *                      *
002100*   ONCE GROUPED THE PROSPECTIVE PAYMENT SUBROUTINE IS CALLED  *
002200*   TO CALCULATE THE TOTAL PAYMENT PRIOR TO DEDUCTIBLE,        *
002300*   CO-INSURANCE, AND CASES WHERE MEDICARE IS SECONDARY PAYOR. *
002400*   THE PROGRAM WILL:                                          *
002500*       1. LOAD THE TABLES USED TO CALCULATE PPS.              *
002600*       2. PASS BACK RETURN CODES.                             *
002700*                                                              *
002800*                  *  *  *  *  *  *  *  *                      *
002900*   THIS SUBROUTINE CALCULATES THE PROVIDER SPECIFIC           *
003000*   ELEMENTS ON A PROVIDER BREAK, THEREFORE IT WILL RUN FASTER *
003100*   WHEN BILLS ARE BATCHED BY PROVIDER.                        *
003200*                  *  *  *  *  *  *  *  *                      *
003300*                                                              *
003400*                                                              *
003500*--------------------------------------------------------------*
003600*   CHANGE LOG.                                                *
003700*--------------------------------------------------------------*
003800*                                                              *
003900*   04/07/2005 - AT THE REQUEST OF FISS, LTDRV___ MODIFIED TO  *
004000*                ONLY READ INPUT DATA AND LOAD TABLES FOR THE  *
004100*                PROVIDER SPECIFIC FILE & WAGE INDEX FILE      *
004200*                IT STILL RECEIVES THE BILL & PPS RECORDS      *
004300*                                                              *
004400*--------------------------------------------------------------*
004500*                                                              *
004600*   04/20/2005 - EFFECTIVE JULY 1, 2005, CBSA (CORE-BASED      *
004700*                STATISTICAL AREA) IS USED IN PLACE OF MSA     *
004800*                (METROPOLITAN STATISTICAL AREA), THE PROGRAM  *
004900*                DETERMINES WHETHER TO USE THE CBSA WAGE INDEX *
005000*                FILE OR MSA WAGE INDEX FILE BASED ON THE BILL *
005100*                DISCHARGE DATE                                *
005200*                                                              *
005300*--------------------------------------------------------------*
005400*                                                              *
005500*   05/02/2005 - ADDED PSF FIELDS - SPECIAL PAY INDICATOR &    *
005600*                SPECIAL WAGE INDEX                            *
005700*                                                              *
005800*--------------------------------------------------------------*
005900*                                                              *
006000*   01/17/2006 - MODIFIED FOR 1ST CICS PACKAGE RELEASE;        *
006100*                TO BE RELEASED APRIL 1, 2006                  *
006200*                                                              *
006300*--------------------------------------------------------------*
006400*                                                              *
006500*   01/19/2006 - PROGRAM NAME CHANGED FROM LTDRV___ TO LTOPN___*
006600*                                                              *
006700*--------------------------------------------------------------*
006800*                                                              *
006900*   05/02/2006 - ADD IPPS CBSA WAGE INDEX TABLE TO THE PROGRAM *
007000*                FOR SHORT STAY PROVISION #4 - STORE & LOAD    *
007100*                                                              *
007200*--------------------------------------------------------------*
007300*                                                              *
007400*   06/19/2006 - CHANGE VERSION FROM 07.0 TO 07.1              *
007500*                                                              *
007600*--------------------------------------------------------------*
007700*                                                              *
007800*   08/09/2006 - UPDATE FOR OCTOBER 2006 VERSION 07.3          *
007900*                                                              *
008000*--------------------------------------------------------------*
008100*                                                              *
008200*   09/06/2006 - UPDATE FOR OCTOBER 2006 VERSION 07.4          *
008300*                                                              *
008400*--------------------------------------------------------------*
008500*                                                              *
008600*   11/16/2006 - CREATED VERSION 07.5 FOR OCTOBER 2006         *
008700*                DUE TO CORRECTION OF THE IME                  *
008800*                MULTIPLIER USED IN THE 4TH SSO                *
008900*                PROVISION (IPPS PORTION), IPPS WAGE INDEX     *
009000*                CHANGE, & REMOVAL OF PPS-RTC 23               *
009100*                                                              *
009200*--------------------------------------------------------------*
009300*                                                              *
009400*   12/28/2006 - CREATED VERSION 07.6 FOR OCTOBER 2006         *
009500*                DUE TO CBSA SIZE LOGIC CORRECTION             *
009600*                ** THIS VERSION WAS NOT RELEASED **           *
009700*                                                              *
009800*--------------------------------------------------------------*
009900*                                                              *
010000*   05/03/2007 - UPDATE FOR JULY 2007 VERSION 08.0             *
010100*                                                              *
010200*--------------------------------------------------------------*
010300*                                                              *
010400*   08/13/2007 - UPDATE FOR OCTOBER 2007 VERSION 08.1          *
010500*                                                              *
010600*--------------------------------------------------------------*
010700*                                                              *
010800*   08/23/2007 - UPDATE FOR OCTOBER 2007 VERSION 08.2          *
010900*                (FOR REVISED IPPS RATES & WAGE INDEX TABLE)   *
011000*                                                              *
011100*--------------------------------------------------------------*
011200*                                                              *
011300*   09/14/2007 - UPDATE FOR OCTOBER 2007 VERSION 08.3          *
011400*                (FOR REVISED IPPS RATES & WAGE INDEX TABLE)   *
011500*                                                              *
011600*--------------------------------------------------------------*
011700*                                                              *
011800*   09/28/2007 - UPDATE FOR OCTOBER 2007 VERSION 08.4          *
011900*                (FOR REVISED IPPS RATES)                      *
012000*                                                              *
012100*--------------------------------------------------------------*
012200*                                                              *
012300*   12/27/2007 - UPDATE FOR OCTOBER 2007 VERSION 08.5          *
012400*                (FOR REVISED SHORT STAY OUTLIER LOGIC)        *
012500*                                                              *
012600*--------------------------------------------------------------*
012700*                                                              *
012800*   02/06/2008 - UPDATE FOR OCTOBER 2007 VERSION 08.6          *
012900*                (FOR REVISED STANDARD FEDERAL RATE &          *
013000*                 FIXED LOSS AMOUNT FOR APRIL 2008)            *
013100*                                                              *
013200*--------------------------------------------------------------*
013300*                                                              *
013400*   05/08/2008 - CREATED VERSION 09.0 FOR JULY 2008            *
013500*                (FOR NEW RATE YEAR 2009, STILL FY 2008)       *
013600*                                                              *
013700*--------------------------------------------------------------*
013800*                                                              *
013900*   05/19/2008 - CREATED VERSION 09.1 FOR JULY 2008            *
014000*                REVISED IPPS PUERTO RICO RATES                *
014100*                EFFECTIVE RETROACTIVE TO 10/01/2007           *
014200*                                                              *
014300*--------------------------------------------------------------*
014400*                                                              *
014500*   08/11/2008 - CREATED VERSION 09.2 FOR OCTOBER 2008         *
014600*                (FOR RATE YEAR 2009, FY 2009)                 *
014700*                ADDED FIELD P-VAL-BASED-PURCH-SCORE TO THE    *
014800*                PSF (TO BE USED IN IPPS 01/01/2008).          *
014900*                                                              *
015000*--------------------------------------------------------------*
015100*                                                              *
015200*   09/09/2008 - CREATED VERSION 09.3 FOR OCTOBER 2008         *
015300*                (FOR RATE YEAR 2009, FY 2009)                 *
015400*                                                              *
015500*--------------------------------------------------------------*
015600*                                                              *
015700*   02/17/2009 - CREATED VERSION 09.4 FOR OCTOBER 2008         *
015800*                (FOR RATE YEAR 2009, FY 2009)                 *
015900*                                                              *
016000*--------------------------------------------------------------*
016100*                                                              *
016200*   05/18/2009 - CREATED VERSION 09.5 FOR JUNE 3 - SEPT 30 2009*
016300*                (FOR RATE YEAR 2009, FY 2009)                 *
016400*                                                              *
016500*--------------------------------------------------------------*
016600*                                                              *
016700*   08/05/2009 - CREATED VERSION 10.0 FOR OCTOBER 2009         *
016800*                (FOR RATE YEAR 2010, FY 2010)                 *
016900*                                                              *
017000*--------------------------------------------------------------*
017100*                                                              *
017200*   09/03/2009 - CREATED VERSION 10.1 FOR OCTOBER 2009         *
017300*                (FOR RATE YEAR 2010, FY 2010)                 *
017400*                                                              *
017500*--------------------------------------------------------------*
017600*                                                              *
017700*   11/11/2009 - CREATED VERSION 10.2 FOR OCTOBER 2009         *
017800*                (FOR RATE YEAR 2010, FY 2010)                 *
017900*                                                              *
018000*--------------------------------------------------------------*
018100*                                                              *
018200*   04/07/2010 - CREATED VERSION 10.3 FOR OCTOBER 2009         *
018300*                (FOR RATE YEAR 2010, FY 2010)                 *
018400*                                                              *
018500*--------------------------------------------------------------*
018600*                                                              *
018700*   04/19/2010 - CREATED VERSION 10.4 FOR OCTOBER 2009         *
018800*                (FOR RATE YEAR 2010, FY 2010)                 *
018900*                                                              *
019000*--------------------------------------------------------------*
019100*                                                              *
019200*   08/04/2010 - CREATED VERSION 11.0 FOR OCTOBER 2010         *
019300*                (FOR RATE YEAR 2011, FY 2011)                 *
019400*                                                              *
019500*--------------------------------------------------------------*
019600*                                                              *
019700*   10/20/2010 - CREATED VERSION 11.1 FOR OCTOBER 2010         *
019800*                (FOR RATE YEAR 2011, FY 2011)                 *
019900*                ALLOWS DATES OF SERVICE OLDER THAN 5 YEARS    *
020000*--------------------------------------------------------------*
020100*                                                              *
020200*   08/01/2011 - CREATED VERSION 12.0 FOR OCTOBER 2011         *
020300*                (FOR RATE YEAR 2012, FY 2012)                 *
020400*                                                              *
020500*--------------------------------------------------------------*
020600*                                                              *
020700*   08/31/2011 - CREATED VERSION 12.1 FOR OCTOBER 2011         *
020800*                (FOR RATE YEAR 2012, FY 2012)                 *
020900*                                                              *
021000*--------------------------------------------------------------*
021100*                                                              *
021200*   10/28/2011 - CREATED VERSION 12.2 FOR OCTOBER 2011         *
021300*                (FOR RATE YEAR 2012, FY 2012)                 *
021400*                                                              *
021500*--------------------------------------------------------------*
021600*                                                              *
021700*   12/09/2011 - CREATED VERSION 12.3 FOR OCTOBER 2011         *
021800*                (FOR RATE YEAR 2012, FY 2012)                 *
021900*                                                              *
022000*--------------------------------------------------------------*
022100*                                                              *
022200*   07/31/2012 - CREATED VERSION 13.0 FOR OCTOBER 2012         *
022300*                (FOR RATE YEAR 2013, FY 2013)                 *
022400*                                                              *
022500*--------------------------------------------------------------*
022600*                                                              *
022700*   07/31/2012 - CREATED VERSION 13.0 FOR OCTOBER 2012         *
022800*                (FOR RATE YEAR 2013, FY 2013)                 *
022900*                                                              *
023000*--------------------------------------------------------------*
023100*                                                              *
023200*   11/16/2012 - IN VERSION 13.0 OF THE LTCH PPS PRICER        *
023300*                CHANGED "T-CBSA-DATA  OCCURS 0 TO 4000 TIMES" *
023400*                     TO "T-CBSA-DATA  OCCURS 0 TO 7000 TIMES" *
023500*                FOR IPPS-CBSA-WI-TABLE IN RESPONSE TO         *
023600*                HPAR CR8041H2 (R41212).  NO VERSION NUMBERS   *
023700*                CHANGED AND ONLY MODULES LTDRV130 AND         *
023800*                LTOPN130 CHANGED AS DESCRIBED ABOVE.          *
023900*                                                              *
024000*--------------------------------------------------------------*
024100*                                                              *
024200*   08/12/2013 - CREATED VERSION 14.0 FOR OCTOBER 2013         *
024300*                (FOR RATE YEAR 2014, FY 2014)                 *
024400*              - ADDED HOSPITAL QUALITY INDICATOR TO PSF       *
024500*                                                              *
024600*--------------------------------------------------------------*
024700*                                                              *
024800*   09/04/2013 - CREATED VERSION 14.1                          *
024900*              - INCORPORATED CHANGES TO LTCH AND IPPS WAGE    *
025000*                INDEX TABLES                                  *
025100*                                                              *
025200*                                                              *
025300*--------------------------------------------------------------*
025400*                                                              *
025500*   08/07/2014 - CREATED VERSION 15.0                          *
025600*                                                              *
025700*--------------------------------------------------------------*
025800*                                                              *
025900*   09/03/2014 - CREATED VERSION 15.1                          *
026000*                                                              *
026100*   11/20/2014 - CREATED VERSION 15.2                          *
026200*                                                              *
026300*   03/20/15 - VERSION 15.3 CREATED TO ADD NEW DATA NAMES      *
026400*                                                              *
026500*   06/29/15 - VERSION 16.B CREATED TO TEST UPDATED LOGIC      *
026600*                                                              *
026700*   08/05/15 - VERSION 16.0 CREATED TO TEST UPDATED LOGIC      *
026800*                                                              *
026900*   11/25/15 - VERSION 16.C CREATED TO TEST UPDATED INTERFACE  *
027000*              (BILL-NEW-DATA - ADDED COST REPORT DAYS) &      *
027100*              LOGIC                                           *
027200*                                                              *
027300*   12/11/15 - VERSION 16.1 CREATED TO IMPLEMENT CR9401 4-1-16 *
027400*                                                              *
027500*   01/08/16 - VERSION 16.2                                    *
027600*                                                              *
027700* 5-23-16 - VERSION 17.B
027800* 6-7-16 CHANGED THE SEARCH OF THE PSF FROM A BINARY TO A
027900* SEQUENTIAL SEARCH
028000* 7-18-16 - VERSION 17.0
028100* 8-8-17 - VERSION 18.0
028200* 9-21-17 - VERSION 18.1
028300* 10-5-17 - VERSION 18.2
028400****************************************************************
028500
028600 ENVIRONMENT DIVISION.
028700 CONFIGURATION SECTION.
028800 SOURCE-COMPUTER.            IBM-370.
028900 OBJECT-COMPUTER.            IBM-370.
029000 INPUT-OUTPUT  SECTION.
029100 FILE-CONTROL.
029200
029300     SELECT PROV-FILE ASSIGN       TO  UT-S-PPSPROV
029400            FILE STATUS IS PROV-STAT.
029500     SELECT CBSAX-FILE ASSIGN      TO  UT-S-PPSCBSAX
029600            FILE STATUS IS CBSAX-STAT.
029700     SELECT IPPS-CBSAX-FILE ASSIGN TO  UT-S-IPCBSAX
029800            FILE STATUS IS IPPS-CBSAX-STAT.
029900     SELECT MSAX-FILE ASSIGN       TO  UT-S-PPSMSAX
030000            FILE STATUS IS MSAX-STAT.
030100
030200 DATA DIVISION.
030300 FILE SECTION.
030400
030500 FD  PROV-FILE
030600     RECORDING MODE IS F
030700     LABEL RECORDS ARE STANDARD
030800     BLOCK CONTAINS 0 RECORDS.
030900 01  PROV-REC.
031000     05  PROV-PART1                 PIC X(80).
031100     05  PROV-PART2                 PIC X(80).
031200     05  PROV-PART3                 PIC X(80).
031300
031400 FD  CBSAX-FILE
031500     RECORDING MODE IS F
031600     LABEL RECORDS ARE STANDARD
031700     BLOCK CONTAINS 0 RECORDS.
031800***************************************************************
031900*    THIS RECORD IS SUPPLIED BY CMS AND CONTAINS              *
032000*    THE WAGE INDEX FOR THE STATES (RURAL) AND CBSA'S (URBAN).*
032100***************************************************************
032200 01  CBSAX-REC.
032300     05  X-CBSA-X.
032400         10  M-BLANK                PIC X(03).
032500         10  M-STATE                PIC 9(02).
032600     05  X-CBSA REDEFINES X-CBSA-X  PIC 9(05).
032700     05  FILLER                     PIC X(01).
032800     05  XE-DATE-C.
032900         10  XE-C-CC                PIC 9(02).
033000         10  XE-C-YY                PIC 9(02).
033100         10  XE-C-MM                PIC 9(02).
033200         10  XE-C-DD                PIC 9(02).
033300     05  FILLER                     PIC X(01).
033400     05  X-WAGE-INDEX1-C            PIC S9(02)V9(04).
033500     05  FILLER                     PIC X(01).
033600     05  X-WAGE-INDEX2-C            PIC S9(02)V9(04).
033700     05  FILLER                     PIC X(01).
033800     05  X-WAGE-INDEX3-C            PIC S9(02)V9(04).
033900     05  FILLER                     PIC X(01).
034000     05  X-STATE-CBSA-NAME          PIC X(39).
034100     05  FILLER                     PIC X(05).
034200
034300 FD  IPPS-CBSAX-FILE
034400     RECORDING MODE IS F
034500     LABEL RECORDS ARE STANDARD
034600     BLOCK CONTAINS 0 RECORDS.
034700***************************************************************
034800*    THIS RECORD IS SUPPLIED BY CMS AND CONTAINS THE IPPS     *
034900*    WAGE INDEX FOR THE STATES (RURAL) AND CBSA'S (URBAN).    *
035000***************************************************************
035100 01  F-IPPS-CBSA-REC.
035200     05  F-CBSA.
035300         10  F-CBSA-BLANK                PIC X(03).
035400         10  F-CBSA-STATE                PIC 9(02).
035500     05  F-CBSA9  REDEFINES F-CBSA       PIC 9(05).
035600     05  F-CBSA-SIZE             PIC X(01).
035700     05  F-CBSA-EFF-DATE.
035800         10  F-CBSA-CC           PIC 9(02).
035900         10  F-CBSA-YY           PIC 9(02).
036000         10  F-CBSA-MM           PIC 9(02).
036100         10  F-CBSA-DD           PIC 9(02).
036200     05  FILLER                  PIC X(01).
036300     05  F-CBSA-WAGE-INDX1       PIC S9(02)V9(04).
036400     05  FILLER                  PIC X(01).
036500     05  F-CBSA-WAGE-INDX2       PIC S9(02)V9(04).
036600     05  FILLER                  PIC X(01).
036700     05  F-CBSA-STATE-NAME       PIC X(50).
036800     05  FILLER                  PIC X(01).
036900
037000 FD  MSAX-FILE
037100     RECORDING MODE IS F
037200     LABEL RECORDS ARE STANDARD
037300     BLOCK CONTAINS 0 RECORDS.
037400***************************************************************
037500*    THIS RECORD IS SUPPLIED BY CMS AND CONTAINS              *
037600*    THE WAGE INDEX FOR THE STATES (RURAL) AND MSA'S (URBAN). *
037700***************************************************************
037800 01  MSAX-REC.
037900     05  X-MSA-X.
038000         10  M-BLANK                PIC X(02).
038100         10  M-STATE                PIC 9(02).
038200     05  X-MSA REDEFINES X-MSA-X    PIC 9(04).
038300     05  FILLER                     PIC X(01).
038400     05  XE-DATE-M.
038500         10  XE-M-CC                PIC 9(02).
038600         10  XE-M-YY                PIC 9(02).
038700         10  XE-M-MM                PIC 9(02).
038800         10  XE-M-DD                PIC 9(02).
038900     05  FILLER                     PIC X(01).
039000     05  X-WAGE-INDEX1-M            PIC S9(02)V9(04).
039100     05  FILLER                     PIC X(01).
039200     05  X-WAGE-INDEX2-M            PIC S9(02)V9(04).
039300     05  FILLER                     PIC X(01).
039400     05  X-WAGE-INDEX3-M            PIC S9(02)V9(04).
039500     05  FILLER                     PIC X(01).
039600     05  X-STATE-MSA-NAME           PIC X(44).
039700     05  FILLER                     PIC X(01).
039800
039900 WORKING-STORAGE SECTION.
040000 77  W-STORAGE-REF                  PIC X(48) VALUE
040100     'L T O P N _ _ _ - W O R K I N G   S T O R A G E'.
040200 01  OPN-VERSION                    PIC X(05) VALUE '018.2'.
040300 01  LTDRV182                       PIC X(08) VALUE 'LTDRV182'.
040400 01  TABLES-LOADED-SW               PIC 9(01) VALUE 0.
040500 01  EOF-SW                         PIC 9(01) VALUE 0.
040600
040700*****************************************************
040800* PROVIDER RECORD THAT CAN BE PASSED IN FROM THE    *
040900* USER                                              *
041000*****************************************************
041100 01  W-PROV-NEW-HOLD.
041200     02  W-PROV-NEWREC-HOLD1.
041300         05  W-P-NEW-NPI10.
041400             10  W-P-NEW-NPI8             PIC X(08).
041500             10  W-P-NEW-NPI-FILLER       PIC X(02).
041600         05  W-P-NEW-PROVIDER-OSCAR-NO.
041700             10  W-P-NEW-STATE            PIC X(02).
041800             10  FILLER                   PIC X(04).
041900         05  W-P-NEW-DATE-DATA.
042000             10  W-P-NEW-EFF-DATE.
042100                 15  W-P-NEW-EFF-DT-CC    PIC 9(02).
042200                 15  W-P-NEW-EFF-DT-YY    PIC 9(02).
042300                 15  W-P-NEW-EFF-DT-MM    PIC 9(02).
042400                 15  W-P-NEW-EFF-DT-DD    PIC 9(02).
042500             10  W-P-NEW-FY-BEGIN-DATE.
042600                 15  W-P-NEW-FY-BEG-DT-CC PIC 9(02).
042700                 15  W-P-NEW-FY-BEG-DT-YY PIC 9(02).
042800                 15  W-P-NEW-FY-BEG-DT-MM PIC 9(02).
042900                 15  W-P-NEW-FY-BEG-DT-DD PIC 9(02).
043000             10  W-P-NEW-REPORT-DATE.
043100                 15  W-P-NEW-REPORT-DT-CC PIC 9(02).
043200                 15  W-P-NEW-REPORT-DT-YY PIC 9(02).
043300                 15  W-P-NEW-REPORT-DT-MM PIC 9(02).
043400                 15  W-P-NEW-REPORT-DT-DD PIC 9(02).
043500             10  W-P-NEW-TERMINATION-DATE.
043600                 15  W-P-NEW-TERM-DT-CC   PIC 9(02).
043700                 15  W-P-NEW-TERM-DT-YY   PIC 9(02).
043800                 15  W-P-NEW-TERM-DT-MM   PIC 9(02).
043900                 15  W-P-NEW-TERM-DT-DD   PIC 9(02).
044000         05  W-P-NEW-WAIVER-CODE          PIC X(01).
044100             88  W-P-NEW-WAIVER-STATE       VALUE 'Y'.
044200         05  W-P-NEW-INTER-NO             PIC X(05).
044300         05  W-P-NEW-PROVIDER-TYPE        PIC X(02).
044400         05  W-P-NEW-CURRENT-CENSUS-DIV   PIC X(01).
044500         05  W-P-NEW-MSA-DATA.
044600             10  W-P-NEW-CHG-CODE-INDEX    PIC X.
044700             10  W-P-NEW-GEO-LOC-MSA        PIC X(04) JUST RIGHT.
044800             10  W-P-NEW-WAGE-INDEX-LOC-MSA PIC X(04) JUST RIGHT.
044900             10  W-P-NEW-STAND-AMT-LOC-MSA  PIC X(04) JUST RIGHT.
045000             10  W-P-NEW-STAND-AMT-LOC-MSA9
045100       REDEFINES W-P-NEW-STAND-AMT-LOC-MSA.
045200                 15  W-P-NEW-RURAL-1ST.
045300                     20  W-P-NEW-STAND-RURAL  PIC XX.
045400                 15  W-P-NEW-RURAL-2ND        PIC XX.
045500         05  W-P-NEW-SOL-COM-DEP-HOSP-YR PIC XX.
045600         05  W-P-NEW-LUGAR               PIC X.
045700         05  W-P-NEW-TEMP-RELIEF-IND     PIC X.
045800         05  W-P-NEW-FED-PPS-BLEND-IND   PIC X.
045900         05  FILLER                      PIC X(05).
046000     02  W-PROV-NEWREC-HOLD2.
046100         05  W-P-NEW-VARIABLES.
046200             10  W-P-NEW-FAC-SPEC-RATE     PIC  X(07).
046300             10  W-P-NEW-COLA              PIC  X(04).
046400             10  W-P-NEW-INTERN-RATIO      PIC  X(05).
046500             10  W-P-NEW-BED-SIZE          PIC  X(05).
046600             10  W-P-NEW-CCR               PIC  X(04).
046700             10  W-P-NEW-CMI               PIC  X(05).
046800             10  W-P-NEW-SSI-RATIO         PIC  X(04).
046900             10  W-P-NEW-MEDICAID-RATIO    PIC  X(04).
047000             10  W-P-NEW-PPS-BLEND-YR-IND  PIC  X(01).
047100             10  W-P-NEW-PRUP-UPDTE-FACTOR PIC  9(01)V9(05).
047200             10  W-P-NEW-DSH-PERCENT       PIC  V9(04).
047300             10  W-P-NEW-FYE-DATE.
047400                 15  W-P-NEW-FYE-CC        PIC 99.
047500                 15  W-P-NEW-FYE-YY        PIC 99.
047600                 15  W-P-NEW-FYE-MM        PIC 99.
047700                 15  W-P-NEW-FYE-DD        PIC 99.
047800         05  W-P-NEW-SPECIAL-PAY-IND       PIC X(01).
047900         05  W-P-NEW-HOSP-QUAL-IND         PIC X(01).
048000         05  W-P-NEW-GEO-LOC-CBSAX         PIC X(05).
048100         05  W-P-NEW-GEO-LOC-CBSA9 REDEFINES
048200                         W-P-NEW-GEO-LOC-CBSAX PIC 9(05).
048300         05  W-P-NEW-GEO-LOC-CBSA-AST REDEFINES
048400                         W-P-NEW-GEO-LOC-CBSA9.
048500             10 W-P-NEW-GEO-LOC-CBSA-1ST   PIC X.
048600             10 W-P-NEW-GEO-LOC-CBSA-2ND   PIC X.
048700             10 W-P-NEW-GEO-LOC-CBSA-3RD   PIC X.
048800             10 W-P-NEW-GEO-LOC-CBSA-4TH   PIC X.
048900             10 W-P-NEW-GEO-LOC-CBSA-5TH   PIC X.
049000         05  FILLER                        PIC X(10).
049100         05  W-P-NEW-SPECIAL-WAGE-INDEX    PIC 9(02)V9(04).
049200     02  W-PROV-NEWREC-HOLD3.
049300         05  W-P-NEW-PASS-AMT-DATA.
049400             10  W-P-NEW-PASS-AMT-CAPITAL    PIC X(06).
049500             10  W-P-NEW-PASS-AMT-DIR-MED-ED PIC X(06).
049600             10  W-P-NEW-PASS-AMT-ORGAN-ACQ  PIC X(06).
049700             10  W-P-NEW-PASS-AMT-PLUS-MISC  PIC X(06).
049800         05  W-P-NEW-CAPI-DATA.
049900             15  W-P-NEW-CAPI-PPS-PAY-CODE   PIC X.
050000             15  W-P-NEW-CAPI-HOSP-SPEC-RATE PIC X(6).
050100             15  W-P-NEW-CAPI-OLD-HARM-RATE  PIC X(6).
050200             15  W-P-NEW-CAPI-NEW-HARM-RATIO PIC X(5).
050300             15  W-P-NEW-CAPI-CSTCHG-RATIO   PIC X(04).
050400             15  W-P-NEW-CAPI-NEW-HOSP       PIC X.
050500             15  W-P-NEW-CAPI-IME            PIC X(05).
050600             15  W-P-NEW-CAPI-EXCEPTIONS     PIC X(6).
050700             15  W-P-VAL-BASED-PURCH-SCORE   PIC X(4).
050800         05  FILLER                        PIC X(18).
050900
051000***************************************************************
051100* FILE STATUS VARIABLES                                       *
051200***************************************************************
051300 01  PROV-STAT.
051400     02  PROV-STAT1          PIC X.
051500     02  PROV-STAT2          PIC X.
051600
051700 01  MSAX-STAT.
051800     02  MSAX-STAT1          PIC X.
051900     02  MSAX-STAT2          PIC X.
052000
052100 01  CBSAX-STAT.
052200     02  CBSAX-STAT1         PIC X.
052300     02  CBSAX-STAT2         PIC X.
052400
052500 01  IPPS-CBSAX-STAT.
052600     02  IPPS-CBSAX-STAT1    PIC X.
052700     02  IPPS-CBSAX-STAT2    PIC X.
052800
052900***************************************************************
053000* CBSA WAGE INDEX TABLE                                       *
053100***************************************************************
053200 01  CBSA-WI-TABLE.
053300     05  C-CBSA-DATA  OCCURS 0 TO 7000 TIMES
053400                      DEPENDING ON CBSA-CNT
053500                      ASCENDING KEY IS CBSAX-CBSA
053600                      INDEXED BY CU1 CU2.
053700         10  CBSAX-CBSA         PIC X(05).
053800         10  CBSAX-EFF-DATE     PIC X(08).
053900         10  CBSAX-WAGE-INDEX1  PIC S9(02)V9(04).
054000         10  CBSAX-WAGE-INDEX2  PIC S9(02)V9(04).
054100         10  CBSAX-WAGE-INDEX3  PIC S9(02)V9(04).
054200
054300***************************************************************
054400* IPPS CBSA WAGE INDEX TABLE                                  *
054500***************************************************************
054600 01  IPPS-CBSA-WI-TABLE.
054700     05  T-CBSA-DATA  OCCURS 0 TO 7000 TIMES
054800                      DEPENDING ON IPPS-CBSA-CNT
054900                      ASCENDING KEY IS T-CBSA
055000                      INDEXED BY MA1 MA2 MA3.
055100         10  T-CBSA             PIC X(5).
055200         10  T-CBSA-SIZE        PIC X(01).
055300         10  T-CBSA-EFF-DATE    PIC X(08).
055400         10  T-CBSA-WAGE-INDX1  PIC S9(02)V9(04).
055500         10  T-CBSA-WAGE-INDX2  PIC S9(02)V9(04).
055600
055700***************************************************************
055800* MSA WAGE INDEX TABLE                                        *
055900***************************************************************
056000 01  MSA-WI-TABLE.
056100     05  M-MSA-DATA   OCCURS 0 TO 4000 TIMES
056200                      DEPENDING ON MSA-CNT
056300                      ASCENDING KEY IS MSAX-MSA
056400                      INDEXED BY MU1 MU2.
056500         10  MSAX-MSA          PIC X(4).
056600         10  MSAX-EFF-DATE     PIC X(08).
056700         10  MSAX-WAGE-INDEX1  PIC S9(02)V9(04).
056800         10  MSAX-WAGE-INDEX2  PIC S9(02)V9(04).
056900         10  MSAX-WAGE-INDEX3  PIC S9(02)V9(04).
057000
057100***************************************************************
057200* RECORD COUNT VARIABLES                                      *
057300***************************************************************
057400 01  WORK-COUNTERS.
057500     05  CBSA-CNT              PIC 9(5) VALUE ZERO.
057600     05  MSA-CNT               PIC 9(5) VALUE ZERO.
057700     05  PROV-CNT              PIC 9(5) VALUE ZERO.
057800     05  IPPS-CBSA-CNT         PIC 9(5) VALUE ZERO.
057900
058000***************************************************************
058100*    THE PROVIDER SPECIFIC INFORMATION TABLE IS INITIALLY     *
058200*    SET TO OCCUR 2400 TIMES. THIS NUMBER SHOULD BE ADJUSTED  *
058300*    BY THE USER TO REFLECT THE NUMBER OF PROVIDER RECORDS    *
058400*    PLUS EXPANSION. EACH ENTRY COSTS 240 BYTES OF MEMORY.    *
058500*    THIS FILE MUST BE IN PROVIDER NUMBER, EFFECTIVE-DATE     *
058600*    SEQUENCE.                                                *
058700***************************************************************
058800 01  PROV-TABLE.
058900     05  PROV-ENTRIES       OCCURS 0 TO 2400 TIMES
059000                            DEPENDING ON PROV-CNT
059100                            ASCENDING KEY IS PROV-NO
059200                            INDEXED BY PX1.
059300         10  PROV-DATA1.
059400             15  PROV-NPI10.
059500                 20  PROV-NPI8       PIC X(08).
059600                 20  PROV-NPI-FILLER PIC X(02).
059700             15  PROV-NO             PIC X(06).
059800             15  PROV-EFF-DATE       PIC X(08).
059900             15  FILLER              PIC X(56).
060000
060100 01  PROV-DATA-2.
060200     05  PROV-ENTRIES2      OCCURS 0 TO 2400 TIMES
060300                            DEPENDING ON PROV-CNT
060400                            INDEXED BY PD2.
060500         10  PROV-DATA2              PIC X(80).
060600
060700 01  PROV-DATA-3.
060800     05  PROV-ENTRIES3      OCCURS 0 TO 2400 TIMES
060900                            DEPENDING ON PROV-CNT
061000                            INDEXED BY PD3.
061100         10  PROV-DATA3              PIC X(80).
061200
061300
061400**************************************************************
061500*      THIS IS THE PROV-RECORD THAT WILL BE PASSED TO        *
061600*      THE LTDRV___ PROGRAM                                  *
061700**************************************************************
061800 01  PROV-NEW-HOLD.
061900     02  PROV-NEWREC-HOLD1.
062000         05  P-NEW-NPI10.
062100             10  P-NEW-NPI8             PIC X(08).
062200             10  P-NEW-NPI-FILLER       PIC X(02).
062300         05  P-NEW-PROVIDER-NO.
062400             10  P-NEW-STATE            PIC 9(02).
062500             10  FILLER                 PIC X(04).
062600         05  P-NEW-DATE-DATA.
062700             10  P-NEW-EFF-DATE.
062800                 15  P-NEW-EFF-DT-CC    PIC 9(02).
062900                 15  P-NEW-EFF-DT-YY    PIC 9(02).
063000                 15  P-NEW-EFF-DT-MM    PIC 9(02).
063100                 15  P-NEW-EFF-DT-DD    PIC 9(02).
063200             10  P-NEW-FY-BEGIN-DATE.
063300                 15  P-NEW-FY-BEG-DT-CC PIC 9(02).
063400                 15  P-NEW-FY-BEG-DT-YY PIC 9(02).
063500                 15  P-NEW-FY-BEG-DT-MM PIC 9(02).
063600                 15  P-NEW-FY-BEG-DT-DD PIC 9(02).
063700             10  P-NEW-REPORT-DATE.
063800                 15  P-NEW-REPORT-DT-CC PIC 9(02).
063900                 15  P-NEW-REPORT-DT-YY PIC 9(02).
064000                 15  P-NEW-REPORT-DT-MM PIC 9(02).
064100                 15  P-NEW-REPORT-DT-DD PIC 9(02).
064200             10  P-NEW-TERMINATION-DATE.
064300                 15  P-NEW-TERM-DT-CC   PIC 9(02).
064400                 15  P-NEW-TERM-DT-YY   PIC 9(02).
064500                 15  P-NEW-TERM-DT-MM   PIC 9(02).
064600                 15  P-NEW-TERM-DT-DD   PIC 9(02).
064700         05  P-NEW-WAIVER-CODE          PIC X(01).
064800             88  P-NEW-WAIVER-STATE       VALUE 'Y'.
064900         05  P-NEW-INTER-NO             PIC 9(05).
065000         05  P-NEW-PROVIDER-TYPE        PIC X(02).
065100         05  P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
065200         05  P-NEW-CURRENT-DIV   REDEFINES
065300                    P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
065400         05  P-NEW-MSA-DATA.
065500             10  P-NEW-CHG-CODE-INDEX       PIC X.
065600             10  P-NEW-GEO-LOC-MSAX         PIC X(04) JUST RIGHT.
065700             10  P-NEW-GEO-LOC-MSA9   REDEFINES
065800                             P-NEW-GEO-LOC-MSAX  PIC 9(04).
065900             10  P-NEW-GEO-LOC-MSA-AST REDEFINES
066000                             P-NEW-GEO-LOC-MSA9.
066100                 15  P-NEW-GEO-MSA-1ST    PIC X.
066200                 15  P-NEW-GEO-MSA-2ND    PIC X.
066300                 15  P-NEW-GEO-MSA-3RD    PIC X.
066400                 15  P-NEW-GEO-MSA-4TH    PIC X.
066500             10  P-NEW-WAGE-INDEX-LOC-MSA   PIC X(04) JUST RIGHT.
066600             10  P-NEW-STAND-AMT-LOC-MSA    PIC X(04) JUST RIGHT.
066700             10  P-NEW-STAND-AMT-LOC-MSA9
066800                   REDEFINES P-NEW-STAND-AMT-LOC-MSA.
066900                 15  P-NEW-RURAL-1ST.
067000                     20  P-NEW-STAND-RURAL  PIC XX.
067100                         88  P-NEW-STD-RURAL-CHECK VALUE '  '.
067200                 15  P-NEW-RURAL-2ND        PIC XX.
067300         05  P-NEW-SOL-COM-DEP-HOSP-YR PIC XX.
067400                 88  P-NEW-SCH-YRBLANK    VALUE   '  '.
067500                 88  P-NEW-SCH-YR82       VALUE   '82'.
067600                 88  P-NEW-SCH-YR87       VALUE   '87'.
067700         05  P-NEW-LUGAR                    PIC X.
067800         05  P-NEW-TEMP-RELIEF-IND          PIC X.
067900         05  P-NEW-FED-PPS-BLEND-IND        PIC X.
068000         05  FILLER                         PIC X(05).
068100     02  PROV-NEWREC-HOLD2.
068200         05  P-NEW-VARIABLES.
068300             10  P-NEW-FAC-SPEC-RATE     PIC  9(05)V9(02).
068400             10  P-NEW-COLA              PIC  9(01)V9(03).
068500             10  P-NEW-INTERN-RATIO      PIC  9(01)V9(04).
068600             10  P-NEW-BED-SIZE          PIC  9(05).
068700             10  P-NEW-CCR               PIC  9(01)V9(03).
068800             10  P-NEW-CMI               PIC  9(01)V9(04).
068900             10  P-NEW-SSI-RATIO         PIC  V9(04).
069000             10  P-NEW-MEDICAID-RATIO    PIC  V9(04).
069100             10  P-NEW-PPS-BLEND-YR-IND  PIC  X(01).
069200             10  P-NEW-PRUP-UPDTE-FACTOR PIC  9(01)V9(05).
069300             10  P-NEW-DSH-PERCENT       PIC  V9(04).
069400             10  P-NEW-FYE-DATE.
069500                 15  P-NEW-FYE-CC        PIC 99.
069600                 15  P-NEW-FYE-YY        PIC 99.
069700                 15  P-NEW-FYE-MM        PIC 99.
069800                 15  P-NEW-FYE-DD        PIC 99.
069900         05  P-NEW-SPECIAL-PAY-IND         PIC X(01).
070000         05  FILLER                        PIC X(01).
070100         05  P-NEW-GEO-LOC-CBSAX           PIC X(05) JUST RIGHT.
070200         05  P-NEW-GEO-LOC-CBSA9 REDEFINES
070300                       P-NEW-GEO-LOC-CBSAX PIC 9(05).
070400         05  P-NEW-GEO-LOC-CBSA-AST REDEFINES
070500                       P-NEW-GEO-LOC-CBSA9.
070600             10 P-NEW-GEO-LOC-CBSA-1ST     PIC X.
070700             10 P-NEW-GEO-LOC-CBSA-2ND     PIC X.
070800             10 P-NEW-GEO-LOC-CBSA-3RD     PIC X.
070900             10 P-NEW-GEO-LOC-CBSA-4TH     PIC X.
071000             10 P-NEW-GEO-LOC-CBSA-STH     PIC X.
071100         05  FILLER                        PIC X(10).
071200         05  P-NEW-SPECIAL-WAGE-INDEX      PIC 9(02)V9(04).
071300     02  PROV-NEWREC-HOLD3.
071400         05  P-NEW-PASS-AMT-DATA.
071500             10  P-NEW-PASS-AMT-CAPITAL    PIC 9(04)V99.
071600             10  P-NEW-PASS-AMT-DIR-MED-ED PIC 9(04)V99.
071700             10  P-NEW-PASS-AMT-ORGAN-ACQ  PIC 9(04)V99.
071800             10  P-NEW-PASS-AMT-PLUS-MISC  PIC 9(04)V99.
071900         05  P-NEW-CAPI-DATA.
072000             15  P-NEW-CAPI-PPS-PAY-CODE   PIC X.
072100             15  P-NEW-CAPI-HOSP-SPEC-RATE PIC 9(04)V99.
072200             15  P-NEW-CAPI-OLD-HARM-RATE  PIC 9(04)V99.
072300             15  P-NEW-CAPI-NEW-HARM-RATIO PIC 9(01)V9999.
072400             15  P-NEW-CAPI-CSTCHG-RATIO   PIC 9V999.
072500             15  P-NEW-CAPI-NEW-HOSP       PIC X.
072600             15  P-NEW-CAPI-IME            PIC 9V9999.
072700             15  P-NEW-CAPI-EXCEPTIONS     PIC 9(04)V99.
072800         05  FILLER                        PIC X(22).
072900
073000
073100***************************************************************
073200 LINKAGE SECTION.
073300***************************************************************
073400
073500***************************************************************
073600*      THIS IS THE BILL-RECORD THAT IS PASSED TO THIS PROGRAM *
073700*      AND WILL BE PASSED TO PROGRAM LTDRV___                 *
073800***************************************************************
073900 01  BILL-NEW-DATA.
074000     05  B-NPI10.
074100         10  B-NPI8                   PIC X(08).
074200         10  B-NPI-FILLER             PIC X(02).
074300     05  B-PROVIDER-NO                PIC X(06).
074400     05  B-PATIENT-STATUS             PIC X(02).
074500     05  B-DRG-CODE                   PIC X(03).
074600     05  B-LOS                        PIC 9(03).
074700     05  B-COV-DAYS                   PIC 9(03).
074800     05  B-LTR-DAYS                   PIC 9(02).
074900     05  B-CST-RPT-DAYS               PIC 9(03).
075000     05  B-DISCHARGE-DATE.
075100         10  B-DISCHG-CC              PIC 9(02).
075200         10  B-DISCHG-YY              PIC 9(02).
075300         10  B-DISCHG-MM              PIC 9(02).
075400         10  B-DISCHG-DD              PIC 9(02).
075500     05  B-COV-CHARGES                PIC 9(07)V9(02).
075600     05  B-SPEC-PAY-IND               PIC X(01).
075700     05  B-REVIEW-CODE                PIC 9(02).
075800     05  B-DIAGNOSIS-CODE-TABLE.
075900         10  B-DIAGNOSIS-CODE         PIC X(07) OCCURS 25 TIMES
076000                                      INDEXED BY IDX-DIAG.
076100     05  B-PROCEDURE-CODE-TABLE.
076200         10 B-PROCEDURE-CODE          PIC X(07) OCCURS 25 TIMES
076300                                      INDEXED BY IDX-PROC.
076400     05  FILLER                       PIC X(20).
076500
076600**************************************************************
076700*      THIS IS THE PPS DATA THAT IS PASSED TO THIS PROGRAM   *
076800*      AND WILL BE PASSED TO PROGRAM LTDRV___                *
076900**************************************************************
077000 01  PPS-DATA-ALL.
077100     05  PPS-RTC                      PIC X(02).
077200     05  PPS-CHRG-THRESHOLD           PIC 9(07)V9(02).
077300     05  PPS-DATA.
077400         10  PPS-MSA                  PIC X(04).
077500         10  PPS-WAGE-INDEX           PIC 9(02)V9(04).
077600         10  PPS-AVG-LOS              PIC 9(02)V9(01).
077700         10  PPS-RELATIVE-WGT         PIC 9(01)V9(04).
077800         10  PPS-OUTLIER-PAY-AMT      PIC 9(07)V9(02).
077900         10  PPS-LOS                  PIC 9(03).
078000         10  PPS-DRG-ADJ-PAY-AMT      PIC 9(07)V9(02).
078100         10  PPS-FED-PAY-AMT          PIC 9(07)V9(02).
078200         10  PPS-FINAL-PAY-AMT        PIC 9(07)V9(02).
078300         10  PPS-FAC-COSTS            PIC 9(07)V9(02).
078400         10  PPS-NEW-FAC-SPEC-RATE    PIC 9(07)V9(02).
078500         10  PPS-OUTLIER-THRESHOLD    PIC 9(07)V9(02).
078600         10  PPS-SUBM-DRG-CODE        PIC X(03).
078700         10  PPS-CALC-VERS-CD         PIC X(05).
078800         10  PPS-REG-DAYS-USED        PIC 9(03).
078900         10  PPS-LTR-DAYS-USED        PIC 9(03).
079000         10  PPS-BLEND-YEAR           PIC 9(01).
079100         10  PPS-COLA                 PIC 9(01)V9(03).
079200         10  FILLER                   PIC X(04).
079300    05  PPS-OTHER-DATA.
079400         10  PPS-NAT-LABOR-PCT        PIC 9(01)V9(05).
079500         10  PPS-NAT-NONLABOR-PCT     PIC 9(01)V9(05).
079600         10  PPS-STD-FED-RATE         PIC 9(05)V9(02).
079700         10  PPS-BDGT-NEUT-RATE       PIC 9(01)V9(03).
079800         10  FILLER                   PIC X(20).
079900    05  PPS-PC-DATA.
080000         10  PPS-COT-IND              PIC X(01).
080100         10  FILLER                   PIC X(20).
080200
080300 01  PPS-CBSA                         PIC X(05).
080400
080500 01  PPS-PAYMENT-DATA.
080600     05  PPS-SITE-NEUTRAL-COST-PMT    PIC 9(07)V99.
080700     05  PPS-SITE-NEUTRAL-IPPS-PMT    PIC 9(07)V99.
080800     05  PPS-STANDARD-FULL-PMT        PIC 9(07)V99.
080900     05  PPS-STANDARD-SSO-PMT         PIC 9(07)V99.
081000
081100*****************************************************************
081200*            THESE ARE THE VERSIONS OF THE LTDRV___             *
081300*           PROGRAMS THAT WILL BE PASSED BACK----               *
081400*          ASSOCIATED WITH THE BILL BEING PROCESSED             *
081500*****************************************************************
081600 01  PRICER-OPT-VERS-SW.
081700     05  PRICER-OPTION-SW               PIC X(01).
081800         88  ALL-TABLES-PASSED          VALUE 'A'.
081900         88  PROV-RECORD-PASSED         VALUE 'P'.
082000     05  PPS-VERSIONS.
082100         10  PPDRV-VERSION              PIC X(05).
082200
082300**************************************************************
082400*      PROVIDER SPECIFIC RECORD                              *
082500**************************************************************
082600 01  PROV-RECORD-FROM-USER.
082700     05  PROV-REC1                  PIC X(80).
082800     05  PROV-REC2                  PIC X(80).
082900     05  PROV-REC3                  PIC X(80).
083000
083100*****************************************************************
083200*      CORE-BASED STATISTICAL AREA RECORD FROM USER (CBSA)      *
083300*****************************************************************
083400 01  CBSAX-TABLE-FROM-USER.
083500     05  FILLER                     PIC X(32000).
083600     05  FILLER                     PIC X(30000).
083700     05  FILLER                     PIC X(30000).
083800
083900*****************************************************************
084000*      IPPS CORE-BASED STATISTICAL AREA RECORD FROM USER (CBSA) *
084100*****************************************************************
084200 01  IPPS-CBSAX-TABLE-FROM-USER.
084300     05  FILLER                     PIC X(32000).
084400     05  FILLER                     PIC X(30000).
084500     05  FILLER                     PIC X(30000).
084600
084700*****************************************************************
084800*      METROPOLITAN STATISTICAL AREA RECORD FROM USER (MSA)     *
084900*****************************************************************
085000 01  MSAX-TABLE-FROM-USER.
085100     05  FILLER                     PIC X(32000).
085200     05  FILLER                     PIC X(30000).
085300     05  FILLER                     PIC X(30000).
085400
085500
085600
085700
085800 PROCEDURE DIVISION  USING BILL-NEW-DATA
085900                           PPS-DATA-ALL
086000                           PPS-CBSA
086100                           PPS-PAYMENT-DATA
086200                           PRICER-OPT-VERS-SW
086300                           PROV-RECORD-FROM-USER
086400                           CBSAX-TABLE-FROM-USER
086500                           IPPS-CBSAX-TABLE-FROM-USER
086600                           MSAX-TABLE-FROM-USER.
086700
086800
086900******************************************************************
087000*                                                                *
087100*    PROCESSING:                                                 *
087200*       A. THIS MODULE WILL LOAD ALL TABLES THE FIRST TIME THIS  *
087300*          SUBROUTINE IS CALLED.                                 *
087400*       B. THIS MODULE WILL CALL THE LTDRV MODULE.               *
087500*       C. THE PROVIDER TABLE AND WAGE INDEX MSA AND CBSA        *
087600*          TABLES WILL BE PASSED TO THE LTDRV PROGRAM.           *
087700*                                                                *
087800******************************************************************
087900
088000     INITIALIZE PPS-DATA-ALL.
088100     INITIALIZE PPS-CBSA.
088200
088300*----------------------------------------------------------*
088400*  RTC = 98  --  BILL DISCHARGE DATE BEFORE 10/01/2002     *
088500*----------------------------------------------------------*
088600     IF B-DISCHARGE-DATE < 20021001
088700        MOVE 98 TO PPS-RTC
088800        GOBACK.
088900
089000
089100******************************************************************
089200 0000-TEST-PRICER-OPTION-SW.
089300******************************************************************
089400
089500*-----------------------------------------------------*
089600* DETERMINE WHICH FILES HAVE BEEN PASSED IN AND CALL  *
089700* THE APPROPRIATE PARAGRAPH                           *
089800*-----------------------------------------------------*
089900     IF PRICER-OPTION-SW  = 'A'
090000        PERFORM 1900-OPTION-SW-A THRU 1900-EXIT
090100     ELSE
090200       IF PRICER-OPTION-SW  = 'P'
090300          PERFORM 2000-OPTION-SW-P THRU 2000-EXIT
090400       ELSE
090500          PERFORM 2100-OPTION-SW THRU 2100-EXIT
090600       END-IF
090700     END-IF.
090800
090900*-----------------------------------------------------*
091000***  GET THE PROVIDER RECORD IF NEEDED                *
091100*-----------------------------------------------------*
091200     IF PROV-RECORD-PASSED OR ALL-TABLES-PASSED
091300        MOVE 00 TO PPS-RTC
091400     ELSE
091500        PERFORM 1200-GET-THIS-PROVIDER THRU 1200-EXIT
091600     END-IF.
091700
091800***  RTC = 59  --  PROVIDER NOT FOUND
091900     IF PPS-RTC = 59
092000        GOBACK.
092100
092200     IF P-NEW-GEO-LOC-CBSAX = SPACES
092300        MOVE ZEROS TO P-NEW-GEO-LOC-CBSAX
092400     END-IF.
092500
092600     IF P-NEW-GEO-LOC-MSAX = SPACES
092700        MOVE ZEROS TO P-NEW-GEO-LOC-MSAX
092800     END-IF.
092900
093000*-----------------------------------------------------*
093100***  CALL LATEST LTDRVYYV PROGRAM                     *
093200*-----------------------------------------------------*
093300     CALL LTDRV182 USING BILL-NEW-DATA
093400                         PPS-DATA-ALL
093500                         PPS-CBSA
093600                         PPS-PAYMENT-DATA
093700                         PRICER-OPT-VERS-SW
093800                         PROV-NEW-HOLD
093900                         CBSA-WI-TABLE
094000                         IPPS-CBSA-WI-TABLE
094100                         MSA-WI-TABLE
094200                         WORK-COUNTERS.
094300
094400     GOBACK.
094500
094600
094700******************************************************************
094800 1200-GET-THIS-PROVIDER.
094900******************************************************************
095000*    ON A PROVIDER BREAK:                                        *
095100*        FIND THE NEW PROVIDER SPECIFIC DATA ELEMENTS            *
095200*    NOTE: IF BILLS ARE SORTED/BATCHED BY PROVIDER, FEWER        *
095300*             TABLE SEARCHES WILL BE NECESSARY.                  *
095400******************************************************************
095500*    IF B-PROVIDER-NO NOT = P-NEW-PROVIDER-NO
095600*       SEARCH ALL PROV-ENTRIES
095700        SET PX1 TO 1.
095800        SEARCH PROV-ENTRIES
095900          AT END
096000             MOVE 59 TO PPS-RTC
096100             GO TO 1200-EXIT
096200          WHEN PROV-NO (PX1) = B-PROVIDER-NO
096300             MOVE 00 TO PPS-RTC
096400             MOVE PROV-DATA1 (PX1) TO PROV-NEWREC-HOLD1
096500             SET PD2 TO PX1
096600             SET PD3 TO PX1
096700             MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2
096800             MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3
096900             PERFORM 1300-GET-CURR-PROV THRU 1300-EXIT
097000               VARYING PX1 FROM PX1 BY 1
097100                 UNTIL PROV-NO (PX1) NOT = B-PROVIDER-NO
097200                   OR PROV-NO (PX1) = '999999'.
097300
097400 1200-EXIT.
097500      EXIT.
097600
097700
097800******************************************************************
097900 1300-GET-CURR-PROV.
098000******************************************************************
098100     IF  B-DISCHARGE-DATE NOT < PROV-EFF-DATE (PX1)
098200         MOVE PROV-DATA1 (PX1) TO PROV-NEWREC-HOLD1
098300         SET PD2 TO PX1
098400         SET PD3 TO PX1
098500         MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2
098600         MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3
098700     END-IF.
098800
098900
099000 1300-EXIT.
099100      EXIT.
099200
099300
099400******************************************************************
099500 1500-LOAD-ALL-TABLES.
099600******************************************************************
099700*    THE FIRST TIME CALLED:                                      *
099800*        LOAD THE PROVIDER SPECIFIC TABLE SUPPLIED BY            *
099900*             THE INTERMEDIARY/USER.                             *
100000*        LOAD MSA, CBSA, & IPPS CBSA TABLES SUPPLIED BY CMS      *
100100******************************************************************
100200     MOVE ALL '9' TO PROV-NEW-HOLD.
100300     MOVE ALL '9' TO PROV-TABLE.
100400     MOVE ALL '9' TO PROV-DATA-2.
100500     MOVE ALL '9' TO PROV-DATA-3.
100600     OPEN INPUT PROV-FILE.
100700     MOVE 0 TO EOF-SW.
100800     SET PX1 TO EOF-SW.
100900
101000*----------------------------------------------------*
101100* LOAD THE PROVIDER TABLE                            *
101200*----------------------------------------------------*
101300     PERFORM 1600-READ-PROV-FILE THRU 1600-EXIT
101400             UNTIL EOF-SW = 1.
101500     CLOSE PROV-FILE.
101600
101700*----------------------------------------------------*
101800* LOAD THE MSA TABLE                                 *
101900*----------------------------------------------------*
102000     MOVE HIGH-VALUES TO MSA-WI-TABLE.
102100     PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT.
102200
102300*----------------------------------------------------*
102400* LOAD THE CBSA TABLE                                *
102500*----------------------------------------------------*
102600     MOVE HIGH-VALUES TO CBSA-WI-TABLE.
102700     PERFORM 1750-LOAD-CBSAX-FILE THRU 1750-EXIT.
102800
102900*----------------------------------------------------*
103000* LOAD THE IPPS CBSA TABLE                           *
103100*----------------------------------------------------*
103200     MOVE HIGH-VALUES TO IPPS-CBSA-WI-TABLE.
103300     PERFORM 1775-LOAD-IPPS-CBSAX-FILE THRU 1775-EXIT.
103400
103500
103600
103700 1500-EXIT.
103800      EXIT.
103900
104000
104100******************************************************************
104200 1600-READ-PROV-FILE.
104300******************************************************************
104400     READ PROV-FILE
104500         AT END
104600             SET PX1 UP BY 1
104700             MOVE ALL '9' TO PROV-DATA1 (PX1)
104800             SET PD2 TO PX1
104900             SET PD3 TO PX1
105000             MOVE ALL '9' TO PROV-DATA2 (PD2)
105100             MOVE ALL '9' TO PROV-DATA3 (PD3)
105200             MOVE 1 TO EOF-SW
105300             DISPLAY 'NUMBER OF PROVIDERS   = ' PROV-CNT.
105400
105500     IF  EOF-SW = 0
105600         ADD 1 TO PROV-CNT
105700         SET PX1 UP BY 1
105800         MOVE PROV-PART1 TO PROV-DATA1 (PX1)
105900         SET PD2 TO PX1
106000         SET PD3 TO PX1
106100         MOVE PROV-PART2 TO PROV-DATA2 (PD2)
106200         MOVE PROV-PART3 TO PROV-DATA3 (PD3)
106300     END-IF.
106400
106500 1600-EXIT.
106600      EXIT.
106700
106800
106900******************************************************************
107000 1700-LOAD-MSAX-FILE.
107100******************************************************************
107200     OPEN INPUT MSAX-FILE.
107300     MOVE 0 TO EOF-SW.
107400     SET MU1 TO EOF-SW.
107500
107600     PERFORM 1800-READ-MSAX-FILE THRU 1800-EXIT
107700                      UNTIL EOF-SW = 1.
107800     CLOSE MSAX-FILE.
107900
108000 1700-EXIT.
108100      EXIT.
108200
108300
108400******************************************************************
108500 1750-LOAD-CBSAX-FILE.
108600******************************************************************
108700     OPEN INPUT CBSAX-FILE.
108800     MOVE 0 TO EOF-SW.
108900     SET CU1 TO EOF-SW.
109000
109100     PERFORM 1850-READ-CBSAX-FILE THRU 1850-EXIT
109200                      UNTIL EOF-SW = 1.
109300     CLOSE CBSAX-FILE.
109400
109500 1750-EXIT.
109600      EXIT.
109700
109800
109900******************************************************************
110000 1775-LOAD-IPPS-CBSAX-FILE.
110100******************************************************************
110200     OPEN INPUT IPPS-CBSAX-FILE.
110300     MOVE 0 TO EOF-SW.
110400     SET MA3 TO EOF-SW.
110500
110600     PERFORM 1875-READ-IPPS-CBSAX-FILE THRU 1875-EXIT
110700                      UNTIL EOF-SW = 1.
110800     CLOSE IPPS-CBSAX-FILE.
110900
111000 1775-EXIT.
111100      EXIT.
111200
111300
111400******************************************************************
111500 1800-READ-MSAX-FILE.
111600******************************************************************
111700     READ MSAX-FILE
111800         AT END
111900             MOVE 1 TO EOF-SW
112000             DISPLAY 'NUMBER OF MSA RECORDS = ' MSA-CNT.
112100
112200     IF EOF-SW = 0
112300        ADD 1 TO MSA-CNT
112400        SET MU1 UP BY 1
112500        MOVE X-MSA-X         TO MSAX-MSA         (MU1)
112600        MOVE XE-DATE-M       TO MSAX-EFF-DATE    (MU1)
112700        MOVE X-WAGE-INDEX1-M TO MSAX-WAGE-INDEX1 (MU1)
112800        MOVE X-WAGE-INDEX2-M TO MSAX-WAGE-INDEX2 (MU1)
112900        MOVE X-WAGE-INDEX3-M TO MSAX-WAGE-INDEX3 (MU1)
113000     END-IF.
113100
113200 1800-EXIT.
113300      EXIT.
113400
113500
113600******************************************************************
113700 1850-READ-CBSAX-FILE.
113800******************************************************************
113900     READ CBSAX-FILE
114000         AT END
114100             MOVE 1 TO EOF-SW
114200             DISPLAY 'NUMBER OF CBSA RECORDS = ' CBSA-CNT.
114300
114400     IF EOF-SW = 0
114500        ADD 1 TO CBSA-CNT
114600        SET CU1 UP BY 1
114700        MOVE X-CBSA-X        TO CBSAX-CBSA        (CU1)
114800        MOVE XE-DATE-C       TO CBSAX-EFF-DATE    (CU1)
114900        MOVE X-WAGE-INDEX1-C TO CBSAX-WAGE-INDEX1 (CU1)
115000        MOVE X-WAGE-INDEX2-C TO CBSAX-WAGE-INDEX2 (CU1)
115100        MOVE X-WAGE-INDEX3-C TO CBSAX-WAGE-INDEX3 (CU1)
115200     END-IF.
115300
115400 1850-EXIT.
115500      EXIT.
115600
115700
115800******************************************************************
115900 1875-READ-IPPS-CBSAX-FILE.
116000******************************************************************
116100     READ IPPS-CBSAX-FILE
116200         AT END
116300             MOVE 1 TO EOF-SW
116400             DISPLAY 'NUMBER OF IP CBSA RECORDS = ' IPPS-CBSA-CNT.
116500
116600     IF EOF-SW = 0
116700        ADD 1 TO IPPS-CBSA-CNT
116800        SET MA3 UP BY 1
116900        MOVE F-CBSA            TO T-CBSA            (MA3)
117000        MOVE F-CBSA-SIZE       TO T-CBSA-SIZE       (MA3)
117100        MOVE F-CBSA-EFF-DATE   TO T-CBSA-EFF-DATE   (MA3)
117200        MOVE F-CBSA-WAGE-INDX1 TO T-CBSA-WAGE-INDX1 (MA3)
117300        MOVE F-CBSA-WAGE-INDX2 TO T-CBSA-WAGE-INDX2 (MA3)
117400     END-IF.
117500
117600 1875-EXIT.
117700      EXIT.
117800
117900
118000******************************************************************
118100 1900-OPTION-SW-A.
118200******************************************************************
118300     MOVE ALL '9' TO PROV-NEW-HOLD.
118400     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
118500
118600     IF TABLES-LOADED-SW = 0
118700
118800*---------------------------------------------------------------*
118900*      MOVE THE MSA FILE FROM USER INTO MSA TABLE               *
119000*---------------------------------------------------------------*
119100          MOVE HIGH-VALUES                TO MSA-WI-TABLE
119200          MOVE MSAX-TABLE-FROM-USER       TO MSA-WI-TABLE
119300
119400*---------------------------------------------------------------*
119500*      MOVE THE CBSA FILE FROM USER INTO CBSA TABLE             *
119600*---------------------------------------------------------------*
119700          MOVE HIGH-VALUES                TO CBSA-WI-TABLE
119800          MOVE CBSAX-TABLE-FROM-USER      TO CBSA-WI-TABLE
119900
120000*---------------------------------------------------------------*
120100*      MOVE THE IPPS CBSA FILE FROM USER INTO CBSA TABLE        *
120200*---------------------------------------------------------------*
120300          MOVE HIGH-VALUES                TO IPPS-CBSA-WI-TABLE
120400          MOVE IPPS-CBSAX-TABLE-FROM-USER TO IPPS-CBSA-WI-TABLE
120500
120600          MOVE 1 TO TABLES-LOADED-SW
120700
120800     END-IF.
120900
121000
121100 1900-EXIT.
121200      EXIT.
121300
121400
121500******************************************************************
121600 2000-OPTION-SW-P.
121700******************************************************************
121800     MOVE ALL '9' TO PROV-NEW-HOLD.
121900     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
122000
122100     IF TABLES-LOADED-SW = 0
122200*---------------------------------------------------------*
122300*      LOAD MSA TABLE                                     *
122400*---------------------------------------------------------*
122500          MOVE HIGH-VALUES TO MSA-WI-TABLE
122600          PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT
122700
122800*---------------------------------------------------------*
122900*      LOAD CBSA TABLE                                    *
123000*---------------------------------------------------------*
123100          MOVE HIGH-VALUES TO CBSA-WI-TABLE
123200          PERFORM 1750-LOAD-CBSAX-FILE THRU 1750-EXIT
123300
123400*---------------------------------------------------------*
123500*      LOAD IPPS CBSA TABLE                               *
123600*---------------------------------------------------------*
123700          MOVE HIGH-VALUES TO IPPS-CBSA-WI-TABLE
123800          PERFORM 1775-LOAD-IPPS-CBSAX-FILE THRU 1775-EXIT
123900
124000          MOVE 1 TO TABLES-LOADED-SW
124100
124200     END-IF.
124300
124400
124500 2000-EXIT.
124600      EXIT.
124700
124800
124900******************************************************************
125000 2100-OPTION-SW.
125100******************************************************************
125200     IF  TABLES-LOADED-SW = 0
125300         PERFORM 1500-LOAD-ALL-TABLES THRU 1500-EXIT
125400         MOVE 1 TO TABLES-LOADED-SW
125500     END-IF.
125600
125700 2100-EXIT.
125800      EXIT.
125900
126000*********************  END OF PROGRAM   **************************
